gentoo resync : 29.12.2022

1 files changed, 61 insertions, 0 deletions

diff --git a/net-firewall/nftlb/nftlb-1.0.6.ebuild b/net-firewall/nftlb/nftlb-1.0.6.ebuild
new file mode 100644
index 000000000000..f1e9170bcbc4
--- /dev/null
+++ b/net-firewall/nftlb/nftlb-1.0.6.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info autotools
+
+DESCRIPTION="nftables load balancer"
+HOMEPAGE="https://github.com/zevenet/nftlb"
+SRC_URI="https://github.com/zevenet/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	net-firewall/nftables:=[modern-kernel]
+	dev-libs/jansson:=
+	dev-libs/libev:=
+"
+RDEPEND="${DEPEND}"
+
+# tests need root access
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}/nftlb-1.0-tests.patch"
+	"${FILESDIR}/nftlb-1.0-musl.patch"
+)
+
+pkg_setup() {
+	local CONFIG_CHECK="
+		~NF_TABLES
+		~NFT_NUMGEN
+		~NFT_HASH
+		~NF_NAT
+		~IP_NF_NAT
+	"
+
+	linux-info_pkg_setup
+
+	if kernel_is lt 4 19; then
+		eerror "${PN} requires kernel version 4.19 or newer"
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_test() {
+	pushd tests >/dev/null || die
+
+	sed -e "s:/var/log/syslog:\"${T}/tests.log\":" \
+		-i exec_tests.sh || die
+
+	./exec_tests.sh || die "tests failed"
+
+	popd >/dev/null || die
+}