1 files changed, 42 insertions, 0 deletions
diff --git a/dev-debug/scap-driver/scap-driver-0.17.3.ebuild b/dev-debug/scap-driver/scap-driver-0.17.3.ebuild
new file mode 100644
index 000000000000..7a16f4888e5b
--- /dev/null
+++ b/dev-debug/scap-driver/scap-driver-0.17.3.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake linux-mod-r1
+
+DESCRIPTION="Kernel module for dev-debug/sysdig"
+HOMEPAGE="https://sysdig.com/"
+SRC_URI="https://github.com/falcosecurity/libs/archive/${PV}.tar.gz -> falcosecurity-libs-${PV}.tar.gz"
+S="${WORKDIR}/libs-${PV}"
+
+LICENSE="Apache-2.0 GPL-2 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="!<dev-debug/sysdig-${PV}[modules]"
+
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+# We need to specify the driver version manually since we do not use a git tree.
+# This version can be found in the corresponding *sysdig* tree in cmake/modules/driver.cmake
+DRIVER_VERSION="7.2.0+driver"
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod, so just pretend to use bundled deps
+		# in order to make it through the cmake setup.
+		-DUSE_BUNDLED_DEPS=ON
+		-DCREATE_TEST_TARGETS=OFF
+		-DDRIVER_VERSION="${DRIVER_VERSION}"
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	local modlist=( scap=:"${BUILD_DIR}"/driver/src )
+	local modargs=( KERNELDIR="${KV_OUT_DIR}" )
+
+	linux-mod-r1_src_compile
+}