1 files changed, 49 insertions, 0 deletions
diff --git a/dev-python/pytest-cov/pytest-cov-2.12.0.ebuild b/dev-python/pytest-cov/pytest-cov-2.12.0.ebuild
new file mode 100644
index 000000000000..8763efa3ffaa
--- /dev/null
+++ b/dev-python/pytest-cov/pytest-cov-2.12.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="py.test plugin for coverage reporting"
+HOMEPAGE="https://github.com/pytest-dev/pytest-cov https://pypi.org/project/pytest-cov/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/py-1.4.22[${PYTHON_USEDEP}]
+	>=dev-python/pytest-3.6[${PYTHON_USEDEP}]
+	>=dev-python/coverage-4.4[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+"
+# TODO: figure out how to make tests work without pytest-cov installed
+# first
+BDEPEND="
+	test? (
+		${RDEPEND}
+		~dev-python/pytest-cov-${PV}[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+		dev-python/fields[${PYTHON_USEDEP}]
+		>=dev-python/process-tests-2.0.2[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-py3doc-enhanced-theme
+
+python_test() {
+	local deselect=(
+		# attempts to install packages via pip (network)
+		tests/test_pytest_cov.py::test_dist_missing_data
+	)
+
+	epytest ${deselect[@]/#/--deselect }
+}