1 files changed, 61 insertions, 0 deletions
diff --git a/media-libs/libtgvoip/libtgvoip-2.4.4_p20211129.ebuild b/media-libs/libtgvoip/libtgvoip-2.4.4_p20211129.ebuild
new file mode 100644
index 000000000000..dbc0508565dd
--- /dev/null
+++ b/media-libs/libtgvoip/libtgvoip-2.4.4_p20211129.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic autotools
+
+DESCRIPTION="VoIP library for Telegram clients"
+HOMEPAGE="https://github.com/telegramdesktop/libtgvoip"
+
+LIBTGVOIP_COMMIT="2cffda6222f07cd7d0aa4627a06fa99b05a3956d"
+SRC_URI="https://github.com/telegramdesktop/libtgvoip/archive/${LIBTGVOIP_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${LIBTGVOIP_COMMIT}"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+IUSE="+dsp +alsa pulseaudio"
+
+DEPEND="
+	dev-libs/openssl:=
+	media-libs/opus
+	alsa? ( media-libs/alsa-lib )
+	dsp? ( media-libs/tg_owt:= )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+REQUIRED_USE="
+	|| ( alsa pulseaudio )
+"
+
+src_prepare() {
+	# Will be controlled by us
+	sed -i -e '/^CFLAGS += -DTGVOIP_NO_DSP/d' Makefile.am || die
+	# https://bugs.gentoo.org/717210
+	echo 'libtgvoip_la_LIBTOOLFLAGS = --tag=CXX' >> Makefile.am || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--disable-dsp  # WebRTC is linked from tg_owt
+		$(use_with alsa)
+		$(use_with pulseaudio pulse)
+	)
+	if use dsp; then
+		append-cppflags "-I${ESYSROOT}/usr/include/tg_owt"
+		append-cppflags "-I${ESYSROOT}/usr/include/tg_owt/third_party/abseil-cpp"
+		append-libs '-ltg_owt'
+	else
+		append-cppflags '-DTGVOIP_NO_DSP'
+	fi
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}