1 files changed, 29 insertions, 21 deletions
diff --git a/net-libs/meanwhile/meanwhile-1.0.2-r1.ebuild b/net-libs/meanwhile/meanwhile-1.0.2-r1.ebuild
index 7a2a8a624595..7d3f38645197 100644
--- a/net-libs/meanwhile/meanwhile-1.0.2-r1.ebuild
+++ b/net-libs/meanwhile/meanwhile-1.0.2-r1.ebuild
@@ -1,45 +1,53 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
-inherit eutils flag-o-matic
+EAPI=7
+
+inherit autotools flag-o-matic
 
 DESCRIPTION="Meanwhile (Sametime protocol) library"
 HOMEPAGE="http://meanwhile.sourceforge.net/"
 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
 
 LICENSE="LGPL-2"
-IUSE="doc debug"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 sparc x86"
+IUSE="doc debug"
 
-RDEPEND=">=dev-libs/glib-2:2"
-
-DEPEND="${RDEPEND}
-	dev-libs/gmp
+RDEPEND="dev-libs/glib:2"
+DEPEND="
+	${RDEPEND}
+	dev-libs/gmp"
+BDEPEND="
 	virtual/pkgconfig
 	doc? ( app-doc/doxygen )"
 
-src_prepare(){
-	epatch "${FILESDIR}/${P}-presence.patch" #239144
-	epatch "${FILESDIR}/${P}-glib2.31.patch" #409081
-
-	#241298
-	sed -i -e "/sampledir/ s:-doc::" samples/Makefile.in || die
+PATCHES=(
+	# bug 239144
+	"${FILESDIR}"/${P}-presence.patch
+	# bug 409081
+	"${FILESDIR}"/${P}-glib2.31.patch
+	# bug 241298
+	"${FILESDIR}"/${P}-gentoo-fhs-samples.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
 }
 
 src_configure() {
-	append-flags "-fno-tree-vrp"
-	local myconf
-	use doc || myconf="${myconf} --enable-doxygen=no"
+	append-cflags -fno-tree-vrp
 
-	econf ${myconf} \
+	econf \
 		--disable-static \
+		--enable-doxygen=$(usex doc) \
 		$(use_enable debug)
 }
 
 src_install() {
-	emake DESTDIR="${D}" install
-	find "${D}" -name '*.la' -exec rm -f {} + || die "la file removal failed"
-	dodoc AUTHORS ChangeLog NEWS README TODO
+	default
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
 }