1 files changed, 50 insertions, 0 deletions
diff --git a/sci-libs/Shapely/Shapely-1.6.4_p2.ebuild b/sci-libs/Shapely/Shapely-1.6.4_p2.ebuild
new file mode 100644
index 000000000000..50528d9087df
--- /dev/null
+++ b/sci-libs/Shapely/Shapely-1.6.4_p2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{5,6} )
+
+inherit distutils-r1 eapi7-ver
+
+DESCRIPTION="Geometric objects, predicates, and operations"
+HOMEPAGE="https://pypi.org/project/Shapely/"
+
+MY_PV="$(ver_cut 1-3).post$(ver_cut 5)"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/Toblerity/${PN}.git"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${PN}-${MY_PV}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="test"
+
+RDEPEND=">=sci-libs/geos-3.3
+	dev-python/numpy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+python_prepare_all() {
+	# fix install path for Cython definition file
+	sed -i \
+		-e "s|\(data_files.*\)'shapely'|\1'share/shapely'|" \
+		setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}/lib" || die
+	cp -r "${S}/tests" . || die
+	py.test tests || die
+}