From 70fb964b97d74b88cbbdd3fcbf5871d57323dfd3 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 11 Feb 2024 11:34:48 +0000
Subject: gentoo auto-resync : 11:02:2024 - 11:34:48

---
 app-arch/unp/unp-2.0_pre10.ebuild | 52 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 app-arch/unp/unp-2.0_pre10.ebuild

(limited to 'app-arch/unp/unp-2.0_pre10.ebuild')

diff --git a/app-arch/unp/unp-2.0_pre10.ebuild b/app-arch/unp/unp-2.0_pre10.ebuild
new file mode 100644
index 000000000000..c719be032835
--- /dev/null
+++ b/app-arch/unp/unp-2.0_pre10.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 strip-linguas
+
+DESCRIPTION="Script for unpacking various file formats"
+HOMEPAGE="https://packages.qa.debian.org/u/unp.html"
+MY_PV="${PV/_pre/$'\x7e'pre}"
+SRC_URI="mirror://debian/pool/main/u/unp/${PN}_${MY_PV}.tar.xz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="nls"
+
+DEPEND="nls? ( sys-devel/gettext )"
+
+RDEPEND="${DEPEND}
+	dev-lang/perl"
+
+# tests in upstream tarball are missing sample files
+RESTRICT="test"
+
+src_compile() {
+	if use nls; then
+		strip-linguas -i .
+		if [ -n "$LINGUAS" ]; then
+			emake -C po MOFILES="${LINGUAS// /.po }.po"
+		else
+			emake -C po
+		fi
+	fi
+}
+
+src_install() {
+	dobin unp
+	dosym unp /usr/bin/ucat
+	doman debian/unp.1
+	dodoc debian/changelog debian/README.Debian
+	newbashcomp debian/unp.bash-completion unp
+
+	if use nls; then
+		if [ -n "$LINGUAS" ]; then
+			emake -C po MOFILES="${LINGUAS// /.mo }.mo" DESTDIR="${D}" install
+		else
+			emake -C po DESTDIR="${D}" install
+		fi
+	fi
+}
-- 
cgit v1.2.3