From b982051e7c8e12c3810a0d21d30d687b406b3ae5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 16 Dec 2022 09:35:57 +0000
Subject: gentoo auto-resync : 16:12:2022 - 09:35:57

---
 app-arch/xz-utils/xz-utils-5.2.8.ebuild | 118 --------------------------------
 1 file changed, 118 deletions(-)
 delete mode 100644 app-arch/xz-utils/xz-utils-5.2.8.ebuild

(limited to 'app-arch/xz-utils/xz-utils-5.2.8.ebuild')

diff --git a/app-arch/xz-utils/xz-utils-5.2.8.ebuild b/app-arch/xz-utils/xz-utils-5.2.8.ebuild
deleted file mode 100644
index fb35eaff7363..000000000000
--- a/app-arch/xz-utils/xz-utils-5.2.8.ebuild
+++ /dev/null
@@ -1,118 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# Remember: we cannot leverage autotools in this ebuild in order
-#           to avoid circular deps with autotools
-
-EAPI=7
-
-inherit libtool multilib multilib-minimal preserve-libs usr-ldscript
-
-if [[ ${PV} == 9999 ]] ; then
-	EGIT_REPO_URI="https://git.tukaani.org/xz.git"
-	inherit git-r3 autotools
-
-	# bug #272880 and bug #286068
-	BDEPEND="sys-devel/gettext >=sys-devel/libtool-2"
-else
-	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/lassecollin.asc
-	inherit verify-sig
-
-	MY_P="${PN/-utils}-${PV/_}"
-	SRC_URI="
-		mirror://sourceforge/lzmautils/${MY_P}.tar.gz
-		https://tukaani.org/xz/${MY_P}.tar.gz
-		verify-sig? (
-			https://tukaani.org/xz/${MY_P}.tar.gz.sig
-		)
-	"
-
-	if [[ ${PV} != *_alpha* && ${PV} != *_beta* ]] ; then
-		KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-	fi
-
-	S="${WORKDIR}/${MY_P}"
-fi
-
-DESCRIPTION="Utils for managing LZMA compressed files"
-HOMEPAGE="https://tukaani.org/xz/"
-
-# See top-level COPYING file as it outlines the various pieces and their licenses.
-LICENSE="public-domain LGPL-2.1+ GPL-2+"
-SLOT="0"
-IUSE="+extra-filters nls static-libs"
-
-if [[ ${PV} != 9999 ]] ; then
-	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-lassecollin )"
-fi
-
-# Tests currently do not account for smaller feature set
-RESTRICT="!extra-filters? ( test )"
-
-src_prepare() {
-	default
-
-	if [[ ${PV} == 9999 ]] ; then
-		eautopoint
-		eautoreconf
-	else
-		# Allow building shared libs on Solaris/x64
-		elibtoolize
-	fi
-}
-
-multilib_src_configure() {
-	local myconf=(
-		--enable-threads
-		$(use_enable nls)
-		$(use_enable static-libs static)
-	)
-
-	if ! multilib_is_native_abi ; then
-		myconf+=(
-			--disable-{xz,xzdec,lzmadec,lzmainfo,lzma-links,scripts}
-		)
-	fi
-
-	if ! use extra-filters ; then
-		myconf+=(
-			# LZMA1 + LZMA2 for standard .lzma & .xz files
-			--enable-encoders=lzma1,lzma2
-			--enable-decoders=lzma1,lzma2
-
-			# those are used by default, depending on preset
-			--enable-match-finders=hc3,hc4,bt4
-
-			# CRC64 is used by default, though some (old?) files use CRC32
-			--enable-checks=crc32,crc64
-		)
-	fi
-
-	if [[ ${CHOST} == *-solaris* ]] ; then
-		export gl_cv_posix_shell="${EPREFIX}"/bin/sh
-
-		# Undo Solaris-based defaults pointing to /usr/xpg5/bin
-		myconf+=( --disable-path-for-script )
-	fi
-
-	ECONF_SOURCE="${S}" econf "${myconf[@]}"
-}
-
-multilib_src_install() {
-	default
-
-	gen_usr_ldscript -a lzma
-}
-
-multilib_src_install_all() {
-	find "${ED}" -type f -name '*.la' -delete || die
-	rm "${ED}"/usr/share/doc/${PF}/COPYING* || die
-}
-
-pkg_preinst() {
-	preserve_old_lib /usr/$(get_libdir)/liblzma$(get_libname 0)
-}
-
-pkg_postinst() {
-	preserve_old_lib_notify /usr/$(get_libdir)/liblzma$(get_libname 0)
-}
-- 
cgit v1.2.3