From 62f67115b5c46134c34f88f4b1cbdacc19384c0a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 30 Sep 2018 11:19:18 +0100
Subject: gentoo resync : 30.09.2018

---
 app-crypt/gcr/Manifest          |  2 ++
 app-crypt/gcr/gcr-3.28.0.ebuild | 78 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 80 insertions(+)
 create mode 100644 app-crypt/gcr/gcr-3.28.0.ebuild

(limited to 'app-crypt/gcr')

diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
index 2d114465a99e..d47979b65357 100644
--- a/app-crypt/gcr/Manifest
+++ b/app-crypt/gcr/Manifest
@@ -1,3 +1,5 @@
 DIST gcr-3.20.0.tar.xz 1324216 BLAKE2B dca283d1bde4994ee60666b2d5fdc4f0861df453355dcf20cea22a87808da0b9284506460ecdfe779ab9ecdf4ce17e231bd1d9426d677511684c35e43da19550 SHA512 0acd0fb085a38507b1cc895ac773f91c6f4e14d2ea7e27b8e74c85ef78426597b6ea08ebee696452b0651939ec4a0d8a4a2523c41b3a8a0bd1b0d7b338b1d9c7
+DIST gcr-3.28.0.tar.xz 1329044 BLAKE2B b35bca9b62605c4e0c3d71604ea5e6b7cdd97bb3257aabb26b8834622abdeec29798429b84f88254a1f8b04894f5cac2ef63c2a0bfd47ad32761d8d73cd0b189 SHA512 8d5e650cb369fa889b0adfdc1dc1cb5f8b184881256e6c0a2ed456074a54ceb61d64c0929c093bec66c0d5a15c1718f6e3736a1b25b6d7076081df93b49419e0
 EBUILD gcr-3.20.0.ebuild 1851 BLAKE2B 532e60ee150d6886ea24abda75d29b90acc66f7e055e5941a8c53293dc5491e3850729bc68b8a9f7d5658e0a2b5dd97dc3c0e1a75418fdbf132e0c6b4dbbde29 SHA512 f0c952bff3d6f66c8d75a0671cd886ac0611bd60f7b8a3b29dc71798d545baee9f2e2842ac76a87e34acb05fb200a472fc3bf58d4c0201e5fbaf60bb96efcbbe
+EBUILD gcr-3.28.0.ebuild 1901 BLAKE2B 46b8faea72b8ddedfffdb20e775c523d222d6fd3255a063c3844e511cf2a3e1a6f2d6245fdb590f45379d1e44c68daca46bc97b1a5a785fdd4fb86db4f8b6f8d SHA512 6b19ad07f803bcd73e57d65b5a6d01cc665f1a39e72156d422ad0222f555409573f92fb058c124320534d44b47f9cf943428715663af4a6d1ebc988c022f9668
 MISC metadata.xml 249 BLAKE2B e71e1b95fee768c696704acbf7e3cf0e599ed2bc8de92bae0141d1194ef9e842bdc292798904487a9b90ddfda9b0e84abd3b76b1518576c1d288240e4e46f110 SHA512 c40662134899a5c9f0369a1017806f35adf3280a0b3c91726f7a8ca6012a073a8b471583f5bfb6fe95faac1dcf607e8e2e43f8c91d48ec46f4a8824e2f551506
diff --git a/app-crypt/gcr/gcr-3.28.0.ebuild b/app-crypt/gcr/gcr-3.28.0.ebuild
new file mode 100644
index 000000000000..9bcd03c58103
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.28.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://git.gnome.org/browse/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-3
+
+IUSE="debug gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+COMMON_DEPEND="
+	>=app-crypt/p11-kit-0.19
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=dev-libs/libtasn1-1:=
+	>=sys-apps/dbus-1
+	gtk? ( >=x11-libs/gtk+-3.12:3[X,introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-keyring-3.3
+"
+# gcr was part of gnome-keyring until 3.3
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection-common
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	dev-libs/vala-common
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+# eautoreconf needs:
+#	dev-libs/gobject-introspection-common
+#	dev-libs/vala-common
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable stupid flag changes
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with gtk) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(usex debug --enable-debug=yes --enable-debug=default) \
+		--disable-update-icon-cache \
+		--disable-update-mime
+}
+
+src_test() {
+	virtx emake check
+}
-- 
cgit v1.2.3