From 97f40b36b1afa9726e32962d11f3ac2d0bc5792e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 16 Feb 2023 08:04:03 +0000
Subject: gentoo auto-resync : 16:02:2023 - 08:04:02

---
 app-crypt/tpm2-tools/tpm2-tools-5.5.ebuild | 66 ++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 app-crypt/tpm2-tools/tpm2-tools-5.5.ebuild

(limited to 'app-crypt/tpm2-tools/tpm2-tools-5.5.ebuild')

diff --git a/app-crypt/tpm2-tools/tpm2-tools-5.5.ebuild b/app-crypt/tpm2-tools/tpm2-tools-5.5.ebuild
new file mode 100644
index 000000000000..e463582021ec
--- /dev/null
+++ b/app-crypt/tpm2-tools/tpm2-tools-5.5.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit bash-completion-r1 flag-o-matic python-any-r1
+
+DESCRIPTION="Tools for the TPM 2.0 TSS"
+HOMEPAGE="https://github.com/tpm2-software/tpm2-tools"
+SRC_URI="https://github.com/tpm2-software/tpm2-tools/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+fapi test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=app-crypt/tpm2-tss-3.0.1:=[fapi?]
+	dev-libs/openssl:=
+	net-misc/curl
+	sys-libs/efivar:="
+DEPEND="${RDEPEND}
+	test? (
+		app-crypt/swtpm
+		app-crypt/tpm2-abrmd
+		dev-util/cmocka
+	)"
+BDEPEND="virtual/pkgconfig
+	sys-devel/autoconf-archive
+	test? (
+		app-editors/vim-core
+		dev-tcltk/expect
+		$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	)
+	${PYTHON_DEPS}"
+
+python_check_deps() {
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# tests fail with LTO enabbled. See bug 865275 and 865277
+	filter-lto
+	econf \
+		$(use_enable fapi) \
+		$(use_enable test unit) \
+		--with-bashcompdir=$(get_bashcompdir) \
+		--enable-hardening
+}
+
+src_install() {
+	default
+	mv "${ED}"/$(get_bashcompdir)/tpm2{_completion.bash,} || die
+	local utils=( "${ED}"/usr/bin/tpm2_* )
+	utils=("${utils[@]##*/}")
+	# these utiltites don't have bash completions
+	local nobashcomp=( tpm2_encodeobject tpm2_getpolicydigest tpm2_sessionconfig )
+	mapfile -d $'\0' -t utils < <(printf '%s\0' "${utils[@]}" | grep -Ezvw "${nobashcomp[@]/#/-e}")
+	bashcomp_alias tpm2 "${utils[@]}"
+}
-- 
cgit v1.2.3