From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 app-editors/gedit/Manifest            |  3 ++
 app-editors/gedit/gedit-3.22.1.ebuild | 91 +++++++++++++++++++++++++++++++++++
 app-editors/gedit/metadata.xml        |  8 +++
 3 files changed, 102 insertions(+)
 create mode 100644 app-editors/gedit/Manifest
 create mode 100644 app-editors/gedit/gedit-3.22.1.ebuild
 create mode 100644 app-editors/gedit/metadata.xml

(limited to 'app-editors/gedit')

diff --git a/app-editors/gedit/Manifest b/app-editors/gedit/Manifest
new file mode 100644
index 000000000000..fa9bf8791a19
--- /dev/null
+++ b/app-editors/gedit/Manifest
@@ -0,0 +1,3 @@
+DIST gedit-3.22.1.tar.xz 2948048 BLAKE2B aa23b261bc0a463febf5affbd0dca647df8d1db9553356f145784b1ebed43ed15dfede12f62b3fcb6f00aac59e2d3a84c31627be32000830523a805d46d2e4ab SHA512 7251732f353b1d9dab0fe447fe90b2259df34ff0694d8731ce3be531c21ac82ab6e7f4a07090aeef364640154f4ba6103539a253bc7942952dcf1e331418f0eb
+EBUILD gedit-3.22.1.ebuild 2310 BLAKE2B d792c14afb2d9d87950afe72f2a0887564a7c6a6d6d7fb553ade64f4cde9e841a03bf2157fefb2e26923ae07da12b3527a65142bc6318b1781d1388dc12bbce2 SHA512 5ecdcb8f259361b27743fc29052e0c0a751367f46c6688a31f66942013aca448afd4113d41f7cf923b82bed61fa226e44943aef3dc795fbe3fced74d70663d78
+MISC metadata.xml 249 BLAKE2B e71e1b95fee768c696704acbf7e3cf0e599ed2bc8de92bae0141d1194ef9e842bdc292798904487a9b90ddfda9b0e84abd3b76b1518576c1d288240e4e46f110 SHA512 c40662134899a5c9f0369a1017806f35adf3280a0b3c91726f7a8ca6012a073a8b471583f5bfb6fe95faac1dcf607e8e2e43f8c91d48ec46f4a8824e2f551506
diff --git a/app-editors/gedit/gedit-3.22.1.ebuild b/app-editors/gedit/gedit-3.22.1.ebuild
new file mode 100644
index 000000000000..34c804822997
--- /dev/null
+++ b/app-editors/gedit/gedit-3.22.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+GNOME2_LA_PUNT="yes" # plugins are dlopened
+PYTHON_COMPAT=( python3_{4,5,6} )
+VALA_MIN_API_VERSION="0.26"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils gnome2 multilib python-single-r1 vala virtualx
+
+DESCRIPTION="A text editor for the GNOME desktop"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gedit"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0"
+
+IUSE="+introspection +python spell vala"
+REQUIRED_USE="python? ( introspection ${PYTHON_REQUIRED_USE} )"
+
+KEYWORDS="~alpha amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+
+# X libs are not needed for OSX (aqua)
+COMMON_DEPEND="
+	>=dev-libs/libxml2-2.5.0:2
+	>=dev-libs/glib-2.44:2[dbus]
+	>=x11-libs/gtk+-3.21.3:3[introspection?]
+	>=x11-libs/gtksourceview-3.21.2:3.0[introspection?]
+	>=dev-libs/libpeas-1.14.1[gtk]
+
+	gnome-base/gsettings-desktop-schemas
+	gnome-base/gvfs
+
+	x11-libs/libX11
+
+	introspection? ( >=dev-libs/gobject-introspection-0.9.3:= )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3:3[cairo,${PYTHON_USEDEP}]
+		dev-libs/libpeas[python,${PYTHON_USEDEP}] )
+	spell? ( >=app-text/gspell-0.2.5:0= )
+"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+"
+DEPEND="${COMMON_DEPEND}
+	${vala_depend}
+	app-text/docbook-xml-dtd:4.1.2
+	app-text/yelp-tools
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.50.1
+	>=sys-devel/gettext-0.18
+	virtual/pkgconfig
+"
+# yelp-tools, gnome-common needed to eautoreconf
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"
+
+	gnome2_src_configure \
+		--disable-deprecations \
+		--disable-updater \
+		--enable-gvfs-metadata \
+		$(use_enable introspection) \
+		$(use_enable spell) \
+		$(use_enable python) \
+		$(use_enable vala)
+}
+
+src_test() {
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+	GSETTINGS_SCHEMA_DIR="${S}/data" virtx emake check
+}
+
+src_install() {
+	local args=()
+	# manually set pyoverridesdir due to bug #524018 and AM_PATH_PYTHON limitations
+	use python && args+=( pyoverridesdir="$(python_get_sitedir)/gi/overrides" )
+
+	gnome2_src_install "${args[@]}"
+}
diff --git a/app-editors/gedit/metadata.xml b/app-editors/gedit/metadata.xml
new file mode 100644
index 000000000000..39980802b1da
--- /dev/null
+++ b/app-editors/gedit/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gnome@gentoo.org</email>
+	<name>Gentoo GNOME Desktop</name>
+</maintainer>
+</pkgmetadata>
-- 
cgit v1.2.3