From 2808be9288546424bc5e88a39631a6835e6bd388 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 25 Mar 2024 01:00:59 +0000
Subject: gentoo auto-resync : 25:03:2024 - 01:00:59

---
 app-editors/ghex/ghex-45.2.ebuild | 66 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 app-editors/ghex/ghex-45.2.ebuild

(limited to 'app-editors/ghex/ghex-45.2.ebuild')

diff --git a/app-editors/ghex/ghex-45.2.ebuild b/app-editors/ghex/ghex-45.2.ebuild
new file mode 100644
index 000000000000..334559aea1bf
--- /dev/null
+++ b/app-editors/ghex/ghex-45.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="GNOME hexadecimal editor"
+HOMEPAGE="https://wiki.gnome.org/Apps/Ghex"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/ghex.git"
+	SRC_URI=""
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="GPL-2+ FDL-1.1+"
+IUSE="gtk-doc test"
+RESTRICT="!test? ( test )"
+SLOT="4"
+
+RDEPEND="
+	>=dev-libs/glib-2.68.0:2
+	>=gui-libs/gtk-4.4.0:4[introspection]
+	gui-libs/libadwaita:1
+	dev-libs/gobject-introspection
+	!app-editors/ghex:2
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? ( dev-util/gi-docgen )
+	test? (
+		dev-util/desktop-file-utils
+		dev-libs/appstream-glib
+	)
+	dev-util/gtk-update-icon-cache
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Ddocdir="${EPREFIX}"/usr/share/gtk-doc/
+		-Ddevelopment=false
+		-Dmmap-buffer-backend=true
+		-Ddirect-buffer-backend=true
+		-Dintrospection=enabled
+		$(meson_use gtk-doc gtk_doc)
+		-Dstatic-html-help=false
+		-Dvapi=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3