From d8ae0501eb6c157339ede48ca34513d27470e1dc Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 8 Nov 2023 04:19:34 +0000
Subject: gentoo auto-resync : 08:11:2023 - 04:19:34

---
 app-editors/jove/jove-4.17.5.3.ebuild | 45 +++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 app-editors/jove/jove-4.17.5.3.ebuild

(limited to 'app-editors/jove/jove-4.17.5.3.ebuild')

diff --git a/app-editors/jove/jove-4.17.5.3.ebuild b/app-editors/jove/jove-4.17.5.3.ebuild
new file mode 100644
index 000000000000..503b10d07000
--- /dev/null
+++ b/app-editors/jove/jove-4.17.5.3.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Jonathan's Own Version of Emacs, a light emacs-like editor without LISP bindings"
+HOMEPAGE="https://github.com/jonmacs/jove"
+SRC_URI="https://github.com/jonmacs/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="JOVE"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc"
+
+RDEPEND="sys-libs/ncurses:0="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_compile() {
+	tc-export CC
+
+	myopts=(
+		JOVEHOME="${EPREFIX}/usr" \
+		JMANDIR="${EPREFIX}/usr/share/man/man1" \
+		JDOCDIR="${EPREFIX}/usr/share/doc/${PF}" \
+		OPTFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		LDLIBS="$("$(tc-getPKG_CONFIG)" --libs ncurses)" \
+		SYSDEFS="-DLinux" \
+		$(usev !doc FREFDOCS="")
+	)
+	emake "${myopts[@]}"
+}
+
+src_install() {
+	# The Makefile triggers a rebuild if any of the options have changed
+	# (see recipe for keys.c). So we must pass identical options even if
+	# they're not needed for installation.
+	emake "${myopts[@]}" DESTDIR="${D}" install
+
+	keepdir /var/lib/jove/preserve
+	dodoc README
+}
-- 
cgit v1.2.3