From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 .../docker-compose/docker-compose-1.16.1-r1.ebuild | 71 ++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 app-emulation/docker-compose/docker-compose-1.16.1-r1.ebuild

(limited to 'app-emulation/docker-compose/docker-compose-1.16.1-r1.ebuild')

diff --git a/app-emulation/docker-compose/docker-compose-1.16.1-r1.ebuild b/app-emulation/docker-compose/docker-compose-1.16.1-r1.ebuild
new file mode 100644
index 000000000000..e3bff20d7e04
--- /dev/null
+++ b/app-emulation/docker-compose/docker-compose-1.16.1-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit bash-completion-r1 distutils-r1 vcs-snapshot
+
+MY_PV=${PV//_/}
+
+DESCRIPTION="Multi-container orchestration for Docker"
+HOMEPAGE="https://www.docker.com/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${PN}-${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+CDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/cached-property-1.2.0[${PYTHON_USEDEP}]
+	<dev-python/cached-property-2[${PYTHON_USEDEP}]
+	>=dev-python/dockerpty-0.4.1[${PYTHON_USEDEP}]
+	<dev-python/dockerpty-0.5[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	<dev-python/docker-py-3.0[${PYTHON_USEDEP}]
+	>=dev-python/docopt-0.6.1[${PYTHON_USEDEP}]
+	<dev-python/docopt-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.5.1[${PYTHON_USEDEP}]
+	<dev-python/jsonschema-3[${PYTHON_USEDEP}]
+	>=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}]
+	!~dev-python/PySocks-1.5.7[${PYTHON_USEDEP}]
+	<dev-python/PySocks-2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+	<dev-python/pyyaml-4[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.11.0[${PYTHON_USEDEP}]
+	<dev-python/requests-2.12[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/six-1.3.0[${PYTHON_USEDEP}]
+	<dev-python/six-2[${PYTHON_USEDEP}]
+	>=dev-python/texttable-0.9[${PYTHON_USEDEP}]
+	<dev-python/texttable-0.10[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]
+	<dev-python/websocket-client-1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/enum34-1.0.4[${PYTHON_USEDEP}]' 'python2_7' )
+	$(python_gen_cond_dep '<dev-python/enum34-2[${PYTHON_USEDEP}]' 'python2_7' )
+	$(python_gen_cond_dep '>=dev-python/ipaddress-1.0.16[${PYTHON_USEDEP}]' 'python2_7' )
+	$(python_gen_cond_dep '>=dev-python/backports-ssl-match-hostname-3.5[${PYTHON_USEDEP}]' 'python2_7' )
+"
+DEPEND="
+	${CDEPEND}
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]' 'python2_7' )
+	)
+"
+RDEPEND="${CDEPEND}"
+
+python_test() {
+	${PYTHON} -m pytest tests/unit || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp contrib/completion/bash/docker-compose ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	doins contrib/completion/zsh/*
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3