From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 app-i18n/scim/scim-1.4.18.ebuild | 106 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 106 insertions(+)
 create mode 100644 app-i18n/scim/scim-1.4.18.ebuild

(limited to 'app-i18n/scim/scim-1.4.18.ebuild')

diff --git a/app-i18n/scim/scim-1.4.18.ebuild b/app-i18n/scim/scim-1.4.18.ebuild
new file mode 100644
index 000000000000..cf10edfec8e1
--- /dev/null
+++ b/app-i18n/scim/scim-1.4.18.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit autotools flag-o-matic gnome2-utils qmake-utils
+
+DESCRIPTION="Smart Common Input Method (SCIM) is an Input Method (IM) development platform"
+HOMEPAGE="https://github.com/scim-im/scim"
+SRC_URI="https://github.com/scim-im/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm ~hppa ppc ppc64 sparc x86 ~x86-fbsd"
+IUSE="doc gtk3 qt4"
+
+RDEPEND="x11-libs/libX11
+	dev-libs/glib:2
+	gtk3? ( x11-libs/gtk+:3 )
+	!gtk3? ( x11-libs/gtk+:2 )
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+	)
+	>=dev-libs/atk-1
+	>=x11-libs/pango-1"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen
+		>=app-text/docbook-xsl-stylesheets-1.73.1 )
+	dev-lang/perl
+	virtual/pkgconfig
+	>=dev-util/intltool-0.33
+	sys-devel/libtool"
+DOCS=(
+	README
+	AUTHORS
+	ChangeLog
+	docs/developers
+	docs/scim.cfg
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# bug #83625
+	filter-flags -fvisibility-inlines-hidden -fvisibility=hidden
+	econf $(use_with doc doxygen) \
+		--enable-ld-version-script \
+		$(usex gtk3 --with-gtk-version={3,2}) \
+		--disable-qt3-immodule \
+		$(use_enable qt4 qt4-immodule) \
+		--with-qt4-moc="$(qt4_get_bindir)/moc"
+}
+
+src_compile() {
+	default
+	use doc && emake docs
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${S}/docs/html/" )
+	default
+
+	sed -e "s:@EPREFIX@:${EPREFIX}:" "${FILESDIR}/xinput-${PN}" > "${T}/${PN}.conf" || die
+	insinto /etc/X11/xinit/xinput.d
+	doins "${T}/${PN}.conf"
+}
+
+pkg_postinst() {
+	elog
+	elog "To use SCIM with both GTK and XIM, you should use the following"
+	elog "in your user startup scripts such as .gnomerc or .xinitrc:"
+	elog
+	elog "LANG='your_language' scim -d"
+	elog "export XMODIFIERS=@im=SCIM"
+	elog "export GTK_IM_MODULE=\"scim\""
+	elog "export QT_IM_MODULE=\"scim\""
+	elog
+	elog "where 'your_language' can be zh_CN, zh_TW, ja_JP.eucJP or any other"
+	elog "UTF-8 locale such as en_US.UTF-8 or ja_JP.UTF-8"
+	elog
+	elog "To use Chinese input methods:"
+	elog "	# emerge app-i18n/scim-tables app-i18n/scim-pinyin"
+	elog "To use Korean input methods:"
+	elog "	# emerge app-i18n/scim-hangul"
+	elog "To use Japanese input methods:"
+	elog "	# emerge app-i18n/scim-anthy"
+	elog "To use various input methods (more than 30 languages):"
+	elog "	# emerge app-i18n/scim-m17n"
+	elog
+	elog "Please modify ${EPREFIX}/etc/scim/global and add your UTF-8 locale to"
+	elog "/SupportedUnicodeLocales entry."
+	elog
+	ewarn
+	ewarn "If you upgraded from scim-1.2.x or scim-1.0.x, you should remerge all SCIM modules."
+	ewarn
+
+	gnome2_query_immodules_gtk2
+}
+
+pkg_postrm() {
+	gnome2_query_immodules_gtk2
+}
-- 
cgit v1.2.3