From 77398e424e45d9e98c1cef3c43bdadb9d56e81ef Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 10 Nov 2019 13:21:36 +0000
Subject: gentoo resync : 10.11.2019

---
 app-misc/bb/bb-1.3.0_rc1-r5.ebuild | 71 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 app-misc/bb/bb-1.3.0_rc1-r5.ebuild

(limited to 'app-misc/bb/bb-1.3.0_rc1-r5.ebuild')

diff --git a/app-misc/bb/bb-1.3.0_rc1-r5.ebuild b/app-misc/bb/bb-1.3.0_rc1-r5.ebuild
new file mode 100644
index 000000000000..793a64d7de56
--- /dev/null
+++ b/app-misc/bb/bb-1.3.0_rc1-r5.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+MY_P="${PN}-$(ver_cut 1-2)$(ver_cut 4-5)"
+
+DESCRIPTION="Demonstration program for visual effects of aalib"
+HOMEPAGE="http://aa-project.sourceforge.net/"
+SRC_URI="mirror://sourceforge/aa-project/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="mikmod"
+
+DEPEND="media-libs/aalib:=
+	dev-libs/lzo:=
+	mikmod? ( media-libs/libmikmod:=[openal] )
+"
+# media-libs/libmikmod[openal] is due to bug #516964
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}-$(ver_cut 1-3)"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-noattr.patch
+	"${FILESDIR}"/${P}-fix-protos.patch
+	"${FILESDIR}"/${P}-messager-overlap.patch
+	"${FILESDIR}"/${P}-zbuff-fault.patch
+	"${FILESDIR}"/${P}-printf-cleanup.patch
+	"${FILESDIR}"/${P}-m4-stuff.patch
+	"${FILESDIR}"/${P}-protos.patch
+	"${FILESDIR}"/${P}-disable-pulse.patch
+)
+
+src_prepare() {
+	default
+
+	# unbundle lzo, #515286
+	rm -v README.LZO minilzo.{c,h} mylzo.h || die
+	sed -e 's/minilzo.c//' \
+	    -e 's/minilzo.h//' \
+	    -e 's/README.LZO//' \
+		-i Makefile.am || die
+	echo 'bb_LDADD = -llzo2' >> Makefile.am || die
+	# update code
+	sed -e 's,#include "minilzo.h",#include <lzo/lzo1x.h>,' \
+	    -e 's,int size = image,lzo_uint size = image,' \
+		-i image.c || die
+
+	# rename binary and manpage bb -> bb-aalib
+
+	mv bb.1 bb-aalib.1 || die
+	sed -e 's/bb/bb-aalib/' \
+		-i bb-aalib.1
+	sed -e 's/bin_PROGRAMS = bb/bin_PROGRAMS = bb-aalib/' \
+	    -e 's/man_MANS = bb.1/man_MANS = bb-aalib.1/'     \
+	    -e 's/bb_SOURCES/bb_aalib_SOURCES/'               \
+	    -e 's/bb_LDADD/bb_aalib_LDADD/'                   \
+		-i Makefile.am || die
+
+	mv -v configure.{in,ac} || die
+	eautoreconf
+}
+
+pkg_postinst() {
+	elog "bb binary has been renamed to bb-aalib to avoid a naming conflict with sys-apps/busybox."
+}
-- 
cgit v1.2.3