From b9ef7cab6264f1838672efbbcb4ba3b3abd5323f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 9 Dec 2017 09:14:02 +0000
Subject: gentoo resync : 09.12.2017

---
 app-misc/byobu/byobu-5.124.ebuild | 43 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 app-misc/byobu/byobu-5.124.ebuild

(limited to 'app-misc/byobu/byobu-5.124.ebuild')

diff --git a/app-misc/byobu/byobu-5.124.ebuild b/app-misc/byobu/byobu-5.124.ebuild
new file mode 100644
index 000000000000..f67cbf99d559
--- /dev/null
+++ b/app-misc/byobu/byobu-5.124.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1
+
+DESCRIPTION="A set of profiles for the GNU Screen console window manager (app-misc/screen)"
+HOMEPAGE="http://byobu.co"
+SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${P/-/_}.orig.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="screen"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/newt[${PYTHON_USEDEP}]
+	screen? ( app-misc/screen )
+	!screen? ( app-misc/tmux )"
+
+src_prepare() {
+	default
+
+	python_fix_shebang .
+
+	# Set default system backend to screen
+	if use screen ; then
+		sed -i -e 's/#\(BYOBU_BACKEND\).*/\1="screen"/' etc/byobu/backend || die
+	fi
+}
+
+src_install() {
+	default
+
+	# Create symlinks for backends
+	dosym ${PN} /usr/bin/${PN}-screen
+	dosym ${PN} /usr/bin/${PN}-tmux
+
+	docompress -x /usr/share/doc/${PN}
+}
-- 
cgit v1.2.3