From de49812990871e1705b64051c35161d5e6400269 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 24 Dec 2018 14:11:38 +0000
Subject: gentoo resync : 24.12.2018

---
 app-misc/jq/jq-1.6-r2.ebuild | 61 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 app-misc/jq/jq-1.6-r2.ebuild

(limited to 'app-misc/jq/jq-1.6-r2.ebuild')

diff --git a/app-misc/jq/jq-1.6-r2.ebuild b/app-misc/jq/jq-1.6-r2.ebuild
new file mode 100644
index 000000000000..9463846be754
--- /dev/null
+++ b/app-misc/jq/jq-1.6-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="A lightweight and flexible command-line JSON processor"
+HOMEPAGE="https://stedolan.github.com/jq/"
+SRC_URI="https://github.com/stedolan/jq/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="MIT CC-BY-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x64-macos"
+IUSE="oniguruma static-libs"
+
+DEPEND="
+	>=sys-devel/bison-3.0
+	sys-devel/flex
+	oniguruma? ( dev-libs/oniguruma:=[static-libs?] )
+"
+RDEPEND="
+	!static-libs? (
+		oniguruma? ( dev-libs/oniguruma[static-libs?] )
+	)
+"
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}"/jq-1.6-never-bundle-oniguruma.patch
+		"${FILESDIR}"/jq-1.6-runpath.patch
+		"${FILESDIR}"/jq-1.6-segfault-fix.patch
+	)
+	use oniguruma || { sed -i 's:tests/onigtest::' Makefile.am || die; }
+	sed -i '/^dist_doc_DATA/d' Makefile.am || die
+	sed -i -r "s:(m4_define\(\[jq_version\],) .+\):\1 \[${PV}\]):" \
+		configure.ac || die
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		# don't try to rebuild docs
+		--disable-docs
+		--disable-valgrind
+		--disable-maintainer-mode
+		--enable-rpathhack
+		$(use_enable static-libs static)
+		$(use_with oniguruma)
+	)
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	local DOCS=( AUTHORS README.md )
+	default
+
+	use static-libs || { find "${D}" -name '*.la' -delete || die; }
+}
-- 
cgit v1.2.3