From 21435953e16cda318a82334ddbadb3b5c36d9ea7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 15 Jan 2020 15:51:32 +0000
Subject: gentoo resync : 15.01.2020

---
 app-misc/remind/remind-03.02.00.ebuild | 49 ++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 app-misc/remind/remind-03.02.00.ebuild

(limited to 'app-misc/remind/remind-03.02.00.ebuild')

diff --git a/app-misc/remind/remind-03.02.00.ebuild b/app-misc/remind/remind-03.02.00.ebuild
new file mode 100644
index 000000000000..775c66a900a6
--- /dev/null
+++ b/app-misc/remind/remind-03.02.00.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Ridiculously functional reminder program"
+HOMEPAGE="https://dianne.skoll.ca/projects/remind/"
+SRC_URI="https://dianne.skoll.ca/projects/remind/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="tk"
+
+RDEPEND="
+	tk? ( dev-lang/tk dev-tcltk/tcllib )
+"
+DOCS="docs/WHATSNEW examples/defs.rem www/README.*"
+
+src_prepare() {
+	default
+	sed -i 's:$(MAKE) install:&-nostripped:' "${S}"/Makefile || die
+}
+
+src_test() {
+	if [[ ${EUID} -eq 0 ]] ; then
+		ewarn "Testing fails if run as root. Skipping tests"
+	else
+		emake test
+	fi
+}
+
+src_install() {
+	default
+	dobin www/rem2html
+
+	if ! use tk ; then
+		rm \
+			"${D}"/usr/bin/cm2rem* \
+			"${D}"/usr/bin/tkremind \
+			"${D}"/usr/share/man/man1/cm2rem* \
+			"${D}"/usr/share/man/man1/tkremind* \
+			|| die
+	fi
+
+	rm "${S}"/contrib/rem2ics-*/{Makefile,rem2ics.spec} || die
+	insinto /usr/share/${PN}
+	doins -r contrib/
+}
-- 
cgit v1.2.3