From 8d5dbd847cbc704a6a06405856e94b461011afe3 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 27 Mar 2021 06:06:27 +0000
Subject: gentoo resync : 27.03.2021

---
 app-mobilephone/heimdall/heimdall-1.4.2-r1.ebuild | 48 +++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 app-mobilephone/heimdall/heimdall-1.4.2-r1.ebuild

(limited to 'app-mobilephone/heimdall/heimdall-1.4.2-r1.ebuild')

diff --git a/app-mobilephone/heimdall/heimdall-1.4.2-r1.ebuild b/app-mobilephone/heimdall/heimdall-1.4.2-r1.ebuild
new file mode 100644
index 000000000000..e4026eb23735
--- /dev/null
+++ b/app-mobilephone/heimdall/heimdall-1.4.2-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake udev
+
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="https://github.com/Benjamin-Dobell/Heimdall/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/Heimdall-${PV}"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Benjamin-Dobell/Heimdall.git"
+fi
+
+DESCRIPTION="Tool suite used to flash firmware onto Samsung devices"
+HOMEPAGE="https://glassechidna.com.au/heimdall/ https://github.com/Benjamin-Dobell/Heimdall"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="gui"
+
+RDEPEND="
+	sys-libs/zlib
+	virtual/libusb:1=
+	gui? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_FRONTEND=$(usex !gui)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}"/bin/heimdall
+	use gui && dobin "${BUILD_DIR}"/bin/heimdall-frontend
+	udev_dorules heimdall/60-heimdall.rules
+	dodoc README.md Linux/README
+}
-- 
cgit v1.2.3