From 5a21cec0c36dba03507dcbd5e8ab6698d00b39bf Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 17 Aug 2023 09:31:54 +0100
Subject: gentoo auto-resync : 17:08:2023 - 09:31:54

---
 app-text/atril/Manifest            |   2 +
 app-text/atril/atril-1.27.0.ebuild | 120 +++++++++++++++++++++++++++++++++++++
 2 files changed, 122 insertions(+)
 create mode 100644 app-text/atril/atril-1.27.0.ebuild

(limited to 'app-text/atril')

diff --git a/app-text/atril/Manifest b/app-text/atril/Manifest
index 6a434c90a555..db4d2ede3cae 100644
--- a/app-text/atril/Manifest
+++ b/app-text/atril/Manifest
@@ -1,6 +1,8 @@
 AUX atril-1.26.1-webkitgtk4.1.patch 510 BLAKE2B de6ea9eb6d2f43243d1827655fb25c02b8cd54f7af9a5f9da5b92432b3572b73f419a880d47d36fed5e5db7cf3114b70adac31a50f1cb8611f79933492f02804 SHA512 29e856a258f50b972618fef4efaa8d45269430d7c73bf3454f31b7d5ffa508e07485137a6b94fd71c5a7eb5ef68abedf9e82b98a73f0d78fd4015466d059ba93
 DIST atril-1.26.0.tar.xz 1986160 BLAKE2B 40de33749113144c49341cf8249bd20de37c3d64f3daa865dfe2bcad117e1c2b5aae2aef3b4e0199fd2656b17af236e2a863ef97933decc5072e3419219154e4 SHA512 9c4e8b1c45959136c8fc4c5db47117e45e8afca8be2294418e6c1a0f8098c162ccaa4a60e5baea34db91d45d345a3953afe95281782986e7046b87a34c8f7dbd
 DIST atril-1.26.1.tar.xz 2087068 BLAKE2B d655bffb4a8245bb3cc25fc91d08ba64ade22fb6da24f5fcb9c418c020c99df66c85a0b59f1d0c31a2f450650d9807adc248a7baeb74cb696bf3687270572f47 SHA512 276e80a81234f3228065f3a804fbd8a306ac948978f3dfd233f678dc4fb6f833ebd1123950996ae08869fac112ebb0d2785ab60fde6bfddd2d2c407a2c991ea3
+DIST atril-1.27.0.tar.xz 2082372 BLAKE2B 4f8a3002e9979474be71a7b8d5fda1fc63bc9f3b231dfed7db9a66b0e23acf7d7fd24de070ca55974b19ec4a54d2d95542b84b150ade632087b9e638c6faa404 SHA512 1e8bdf689517be073943b49a81244138d3ebb7783cc45ccc1847eb545ba2897d63a01a5a87b95b359b23760f7f843131ac3f7e2912b0320d9dd5d0f765bfe843
 EBUILD atril-1.26.0-r5.ebuild 2892 BLAKE2B 1c5c90f0f4617595f7c1baf46665c39e673c13d6738e01d926a1e96245bbb4808d2fac27849a313232e5cbca05bd86cf701237f616eb2bdc12b00c967c4481d0 SHA512 5791601f7f01dc146e42c871fd89cf98fe04b026a39e0afd96d7b7e39e1ca849064a6f7fb111dc3401bccde0707498d3f38db145f424d1135cf0c1152da505fc
 EBUILD atril-1.26.1-r1.ebuild 2983 BLAKE2B ffaf46edd7d3607ab12d5c80b950785c4d603edf510ff5df960bd55e9a63158a0e7b5ded9a9e2cf1284ffda1823a3d95cc7e0a16b12ad7170a1d3b6839184dc1 SHA512 597300f0167c0f951687d66862ae4a2ea958c27519329dcfb38c1905170e9a5be1d9da7004341c8da6295b11ab4052e1f996645554e20c2cb71712e9b6c68b32
+EBUILD atril-1.27.0.ebuild 2832 BLAKE2B 1d2e71d31a8dd4ff3be6a18c2b428687b5dfbf53f1f775835c9bf4c02c95b3386c668136da7a3fc84fef1d02fac47c0c5643240cdfd92e2a4bc84a57e9559234 SHA512 ed07d4ac8d2ddd21f39d1eb84e9f837be8b557060e30af048c0a71b75a0abe3d30e8826c198571e2a4810a59b74902805ac95bd32a9490f505498e2838a927fc
 MISC metadata.xml 888 BLAKE2B ce41dbf3197d9cf65fbb39ee5123a6c93979066342a83bab4c28ee65ec41adbe68c787165edc4bd61c2169909c499864a10d6459ba99e80a8fb83c19637b54cb SHA512 b375f7fcc127fd5ff26c0e2516b8d6702627296ea2a1f124b669bff788c4d1adbf0d0052e015063aeba0c1f13fff762effe050729f9ee44cf2e568dc4a80e44d
diff --git a/app-text/atril/atril-1.27.0.ebuild b/app-text/atril/atril-1.27.0.ebuild
new file mode 100644
index 000000000000..7f2d928a2dd0
--- /dev/null
+++ b/app-text/atril/atril-1.27.0.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MATE_LA_PUNT="yes"
+
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit mate python-any-r1 virtualx
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+fi
+
+DESCRIPTION="Atril document viewer for MATE"
+LICENSE="FDL-1.1+ GPL-2+ GPL-3+ LGPL-2+ LGPL-2.1+"
+SLOT="0"
+
+IUSE="caja dbus debug djvu dvi epub +introspection keyring nls +postscript synctex t1lib test tiff xps"
+
+REQUIRED_USE="t1lib? ( dvi )"
+
+COMMON_DEPEND="
+	app-accessibility/at-spi2-core:2
+	app-text/poppler[cairo]
+	dev-libs/glib:2
+	dev-libs/libxml2:2
+	sys-libs/zlib
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3[introspection?]
+	x11-libs/libICE
+	x11-libs/libSM:0
+	x11-libs/libX11
+	x11-libs/cairo
+	x11-libs/pango
+	caja? ( mate-base/caja[introspection?] )
+	djvu? ( app-text/djvu:0 )
+	dvi? (
+		virtual/tex-base
+		t1lib? ( media-libs/t1lib:5 )
+	)
+	epub? (
+		<dev-libs/mathjax-3
+		net-libs/webkit-gtk:4.1
+	)
+	keyring? ( app-crypt/libsecret )
+	introspection? ( dev-libs/gobject-introspection:= )
+	postscript? ( app-text/libspectre )
+	synctex? ( virtual/tex-base )
+	tiff? ( media-libs/tiff:= )
+	xps? ( app-text/libgxps )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	virtual/libintl
+"
+
+BDEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	app-text/yelp-tools
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gtk-doc
+	dev-util/gtk-doc-am
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+#RESTRICT="!test? ( test )"
+# Tests use dogtail and require using accessibility services.
+# Until we figure out how to run successfully, don't run tests
+RESTRICT="test"
+
+PATCHES=(
+	# https://github.com/mate-desktop/atril/issues/582
+	"${FILESDIR}/${PN}-1.26.1-webkitgtk4.1.patch"
+)
+
+python_check_deps() {
+	use test && python_has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# Passing --disable-help would drop offline help, that would be inconsistent
+	# with helps of the most of GNOME apps that doesn't require network for that.
+	mate_src_configure \
+		--enable-comics \
+		--enable-pdf \
+		--enable-pixbuf \
+		--enable-previewer \
+		--enable-thumbnailer \
+		$(use_with keyring) \
+		$(use_enable caja) \
+		$(use_enable dbus) \
+		$(use_enable debug) \
+		$(use_enable djvu) \
+		$(use_enable dvi) \
+		$(use_enable epub) \
+		$(use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable postscript ps) \
+		$(use_enable synctex) \
+		$(use_enable t1lib) \
+		$(use_enable test tests) \
+		$(use_enable tiff) \
+		$(use_enable xps)
+}
+
+src_test() {
+	export GSETTINGS_BACKEND=keyfile
+	gsettings set org.gnome.desktop.interface toolkit-accessibility true || die
+	gsettings set org.mate.interface accessibility true || die
+	virtx emake check
+}
-- 
cgit v1.2.3