From d6fe3a53bdeea6b060d1755199cc2c27492dc14c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 10 Apr 2023 11:36:37 +0100
Subject: gentoo auto-resync : 10:04:2023 - 11:36:36

---
 app-text/groonga/groonga-13.0.1.ebuild | 107 +++++++++++++++++++++++++++++++++
 1 file changed, 107 insertions(+)
 create mode 100644 app-text/groonga/groonga-13.0.1.ebuild

(limited to 'app-text/groonga/groonga-13.0.1.ebuild')

diff --git a/app-text/groonga/groonga-13.0.1.ebuild b/app-text/groonga/groonga-13.0.1.ebuild
new file mode 100644
index 000000000000..bef5cf610056
--- /dev/null
+++ b/app-text/groonga/groonga-13.0.1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit libtool
+
+DESCRIPTION="An Embeddable Fulltext Search Engine"
+HOMEPAGE="https://groonga.org/"
+SRC_URI="https://packages.groonga.org/source/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="benchmark debug doc +exact-alloc-count examples futex jemalloc libedit libevent lzo +mecab msgpack +nfkc sphinx static-libs uyield zeromq zlib zstd"
+REQUIRED_USE="
+	sphinx? ( doc )
+"
+
+DEPEND="
+	>=dev-libs/onigmo-6.1.1:0=
+	dev-libs/rapidjson
+	dev-libs/xxhash
+	benchmark? ( >=dev-libs/glib-2.8 )
+	jemalloc? ( dev-libs/jemalloc:0= )
+	libedit? ( >=dev-libs/libedit-3 )
+	libevent? ( dev-libs/libevent:0= )
+	lzo? ( dev-libs/lzo )
+	mecab? ( >=app-text/mecab-0.80 )
+	msgpack? ( dev-libs/msgpack:= )
+	sphinx? ( >=dev-python/sphinx-1.0.1 )
+	zeromq? ( net-libs/zeromq:0= )
+	zlib? ( sys-libs/zlib:0= )
+	zstd? ( app-arch/zstd:0= )
+"
+RDEPEND="
+	${DEPEND}
+	acct-group/groonga
+	acct-user/groonga
+"
+BDEPEND="
+	virtual/pkgconfig
+	sphinx? ( dev-python/sphinx )
+"
+
+src_prepare() {
+	default
+
+	elibtoolize
+}
+
+src_configure() {
+	# httpd is a bundled copy of nginx; disabled for security reasons
+	# prce only is used with httpd
+	# Apache arrow, kytea and libstemmer are not available in Gentoo repo
+	# ruby is only used for an http test
+	local econfopts=(
+		--disable-groonga-httpd
+		--without-pcre
+		--without-kytea
+		--without-libstemmer
+		--disable-arrow
+		--with-log-path="${EPREFIX}"/var/log/${PN}.log
+		--without-luajit
+		--without-ruby
+		--with-shared-onigmo
+		--with-onigmo=system
+		--with-xxhash
+		$(use_enable benchmark)
+		$(use_enable debug memory-debug)
+		$(use_enable doc document)
+		$(use_enable exact-alloc-count)
+		$(use_enable futex)
+		$(use_with jemalloc)
+		$(use_enable libedit)
+		$(use_with libevent)
+		$(use_with lzo)
+		$(use_with mecab)
+		$(use_enable msgpack message-pack)
+		$(use_with msgpack message-pack "${ESYSROOT}/usr")
+		$(use_enable nfkc)
+		$(use_with sphinx sphinx-build)
+		$(use_enable static-libs static)
+		$(use_enable uyield)
+		$(use_enable zeromq)
+		$(use_with zlib)
+		$(use_with zstd)
+	)
+
+	econf "${econfopts[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+
+	newinitd "${FILESDIR}/${PN}.initd" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+
+	keepdir /var/{log,lib}/${PN}
+	fowners groonga:groonga /var/{log,lib}/${PN}
+
+	if ! use examples ; then
+		rm -r "${ED}/usr/share/${PN}" || die
+	fi
+}
-- 
cgit v1.2.3