From acf34cb86be38d3601273c231058d3fda627e618 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 4 Dec 2022 09:02:03 +0000
Subject: gentoo auto-resync : 04:12:2022 - 09:02:03

---
 dev-ada/libgpr/libgpr-23.0.0.ebuild | 68 +++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 dev-ada/libgpr/libgpr-23.0.0.ebuild

(limited to 'dev-ada/libgpr/libgpr-23.0.0.ebuild')

diff --git a/dev-ada/libgpr/libgpr-23.0.0.ebuild b/dev-ada/libgpr/libgpr-23.0.0.ebuild
new file mode 100644
index 000000000000..6fcb61de1f14
--- /dev/null
+++ b/dev-ada/libgpr/libgpr-23.0.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ADA_COMPAT=( gnat_2021 gcc_12_2_0 )
+inherit ada multiprocessing
+
+MYPN=gprbuild
+MYP=${MYPN}-${PV}
+
+DESCRIPTION="Ada library to handle GPRbuild project files"
+HOMEPAGE="http://libre.adacore.com/"
+SRC_URI="https://github.com/AdaCore/${MYPN}/archive/refs/tags/v${PV}.tar.gz
+		-> ${MYP}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="+shared static-libs static-pic"
+
+RDEPEND="dev-ada/xmlada:=[shared?,static-libs?,static-pic?,${ADA_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+REQUIRED_USE="${ADA_REQUIRED_USE}
+	|| ( shared static-libs static-pic )"
+
+S="${WORKDIR}"/${MYP}
+
+PATCHES=( "${FILESDIR}"/${PN}-2020-gentoo.patch )
+
+src_prepare() {
+	default
+	sed -i -e '/Library_Name/s|gpr|gnatgpr|' gpr/gpr.gpr || die
+}
+
+src_configure() {
+	emake setup
+}
+
+src_compile() {
+	build () {
+		gprbuild -p -m -j$(makeopts_jobs) -XBUILD=production -v \
+			-XLIBRARY_TYPE=$1 -XXMLADA_BUILD=$1 \
+			gpr/gpr.gpr -cargs:C ${CFLAGS} -cargs:Ada ${ADAFLAGS} || die
+	}
+	if use shared; then
+		build relocatable
+	fi
+	if use static-libs; then
+		build static
+	fi
+	if use static-pic; then
+		build static-pic
+	fi
+}
+
+src_install() {
+	if use static-libs; then
+		emake prefix="${D}"/usr libgpr.install.static
+	fi
+	for kind in shared static-pic; do
+		if use ${kind}; then
+			emake prefix="${D}"/usr libgpr.install.${kind}
+		fi
+	done
+	rm -r "${D}"/usr/share/gpr/manifests || die
+	einstalldocs
+}
-- 
cgit v1.2.3