From 1804d2ae908b26fe4e3d3a38646c7d6ffa733d92 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 24 Jan 2024 10:45:40 +0000
Subject: gentoo auto-resync : 24:01:2024 - 10:45:40

---
 dev-debug/lldb/Manifest                |   1 +
 dev-debug/lldb/lldb-19.0.0.9999.ebuild | 106 +++++++++++++++++++++++++++++++++
 2 files changed, 107 insertions(+)
 create mode 100644 dev-debug/lldb/lldb-19.0.0.9999.ebuild

(limited to 'dev-debug/lldb')

diff --git a/dev-debug/lldb/Manifest b/dev-debug/lldb/Manifest
index 5cacd1e921af..3a5ff8139d13 100644
--- a/dev-debug/lldb/Manifest
+++ b/dev-debug/lldb/Manifest
@@ -15,4 +15,5 @@ EBUILD lldb-18.0.0.9999.ebuild 2449 BLAKE2B 33181192b806d4f86c330ebebb31c5509a0e
 EBUILD lldb-18.0.0_pre20240106.ebuild 2678 BLAKE2B d0e53ff05e70dbf3c33ab68810f167bde315c306ad5ceeed2a228fc04f94860c0f6af66eb8c5af41c1ba632c67b609aa50055ae24cc1063535936c0e981162d9 SHA512 c74d1a23f4108f106eb8237334374c466f5e14bd67836dc0cd20341726f2d2e6ac873b43dc5245b973e80924fdb3b325d35368818ce8812280c18e6711ad732b
 EBUILD lldb-18.0.0_pre20240113.ebuild 2678 BLAKE2B d0e53ff05e70dbf3c33ab68810f167bde315c306ad5ceeed2a228fc04f94860c0f6af66eb8c5af41c1ba632c67b609aa50055ae24cc1063535936c0e981162d9 SHA512 c74d1a23f4108f106eb8237334374c466f5e14bd67836dc0cd20341726f2d2e6ac873b43dc5245b973e80924fdb3b325d35368818ce8812280c18e6711ad732b
 EBUILD lldb-18.0.0_pre20240120.ebuild 2678 BLAKE2B d0e53ff05e70dbf3c33ab68810f167bde315c306ad5ceeed2a228fc04f94860c0f6af66eb8c5af41c1ba632c67b609aa50055ae24cc1063535936c0e981162d9 SHA512 c74d1a23f4108f106eb8237334374c466f5e14bd67836dc0cd20341726f2d2e6ac873b43dc5245b973e80924fdb3b325d35368818ce8812280c18e6711ad732b
+EBUILD lldb-19.0.0.9999.ebuild 2449 BLAKE2B 33181192b806d4f86c330ebebb31c5509a0e2a66372dabe5f41bde66da210153c68e50358f46fd3f28ffb5fa734fdb2cf1da2fd3faae4c7d55bb71110362c916 SHA512 6175e13def56fafe7898118a8098d4e603c3a3b15fdc9baa39d8ce483ebd47b2d99350ab6a8b5484f8aee5d7580897a733d6b1927e6702545c2d125dfb22ba73
 MISC metadata.xml 299 BLAKE2B 2feead2cd1b35b3a43335ddd7711f8181b52bc63ee7166608914260c67528add5251349063afbef4f8cf0ec09b2cd4c3ffdd90f2c14ed60bb69ebc03888f6333 SHA512 cd745c54ab18d25bdaff18582105072574103a36cfe7c175ef740f266d00e9fc6f44c332904d23b911c939cf5bdf52973b388923099d8dd5dfef3c283b5cb685
diff --git a/dev-debug/lldb/lldb-19.0.0.9999.ebuild b/dev-debug/lldb/lldb-19.0.0.9999.ebuild
new file mode 100644
index 000000000000..caf23a9a38ee
--- /dev/null
+++ b/dev-debug/lldb/lldb-19.0.0.9999.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake llvm llvm.org python-single-r1
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0/${LLVM_SOABI}"
+IUSE="+debug +libedit lzma ncurses +python test +xml"
+RESTRICT="test"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+DEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	lzma? ( app-arch/xz-utils:= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	xml? ( dev-libs/libxml2:= )
+	~sys-devel/clang-${PV}
+	~sys-devel/llvm-${PV}
+"
+RDEPEND="
+	${DEPEND}
+	python? (
+		${PYTHON_DEPS}
+	)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	python? (
+		>=dev-lang/swig-3.0.11
+	)
+	test? (
+		$(python_gen_cond_dep "
+			~dev-python/lit-${PV}[\${PYTHON_USEDEP}]
+			dev-python/psutil[\${PYTHON_USEDEP}]
+		")
+		sys-devel/lld
+	)
+"
+
+LLVM_COMPONENTS=( lldb cmake llvm/utils )
+LLVM_TEST_COMPONENTS=( llvm/lib/Testing/Support third-party )
+llvm.org_set_globals
+
+pkg_setup() {
+	LLVM_MAX_SLOT=${LLVM_MAJOR} llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	# LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
+	use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
+
+	local mycmakeargs=(
+		-DLLDB_ENABLE_CURSES=$(usex ncurses)
+		-DLLDB_ENABLE_LIBEDIT=$(usex libedit)
+		-DLLDB_ENABLE_PYTHON=$(usex python)
+		-DLLDB_ENABLE_LUA=OFF
+		-DLLDB_ENABLE_LZMA=$(usex lzma)
+		-DLLDB_ENABLE_LIBXML2=$(usex xml)
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLDB_INCLUDE_TESTS=$(usex test)
+
+		-DCLANG_LINK_CLANG_DYLIB=ON
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+
+		-DCLANG_RESOURCE_DIR="../../../clang/${LLVM_MAJOR}"
+
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="$(get_lit_flags)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake_build check-lldb-{shell,unit}
+	# failures + hangs
+	#use python && cmake_build check-lldb-api
+}
+
+src_install() {
+	cmake_src_install
+	find "${D}" -name '*.a' -delete || die
+
+	use python && python_optimize
+}
-- 
cgit v1.2.3