From 88f366f99d8e731ae1a13d9eca9a5284484d2c6f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 28 Feb 2024 05:40:38 +0000
Subject: gentoo auto-resync : 28:02:2024 - 05:40:38

---
 dev-libs/dqlite/dqlite-1.16.4-r1.ebuild | 53 +++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-libs/dqlite/dqlite-1.16.4-r1.ebuild

(limited to 'dev-libs/dqlite/dqlite-1.16.4-r1.ebuild')

diff --git a/dev-libs/dqlite/dqlite-1.16.4-r1.ebuild b/dev-libs/dqlite/dqlite-1.16.4-r1.ebuild
new file mode 100644
index 000000000000..c11ab433bcc7
--- /dev/null
+++ b/dev-libs/dqlite/dqlite-1.16.4-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Embeddable, replicated and fault tolerant SQL engine"
+HOMEPAGE="https://dqlite.io/ https://github.com/canonical/dqlite"
+SRC_URI="https://github.com/canonical/dqlite/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3-with-linking-exception"
+SLOT="0/1.15.1"
+KEYWORDS="amd64 ~arm64 ~x86"
+IUSE="+lz4 test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-db/sqlite:3
+	dev-libs/libuv:=
+	lz4? ( app-arch/lz4:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/dqlite-1.12.0-disable-werror.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-backtrace
+		--disable-debug
+		--disable-sanitize
+		--disable-static
+
+		# Will use bundled raft instead of system raft. See bugs #915960, #925012.
+		--enable-build-raft
+
+		# Will build a bundled libsqlite3.so.
+		--enable-build-sqlite=no
+
+		$(use_with lz4)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3