From 21435953e16cda318a82334ddbadb3b5c36d9ea7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 15 Jan 2020 15:51:32 +0000
Subject: gentoo resync : 15.01.2020

---
 dev-libs/grantlee/grantlee-5.2.0.ebuild | 60 +++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 dev-libs/grantlee/grantlee-5.2.0.ebuild

(limited to 'dev-libs/grantlee/grantlee-5.2.0.ebuild')

diff --git a/dev-libs/grantlee/grantlee-5.2.0.ebuild b/dev-libs/grantlee/grantlee-5.2.0.ebuild
new file mode 100644
index 000000000000..5f7dff2d6d27
--- /dev/null
+++ b/dev-libs/grantlee/grantlee-5.2.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+VIRTUALX_REQUIRED="test"
+inherit cmake virtualx
+
+DESCRIPTION="C++ string template engine based on the Django template system"
+HOMEPAGE="https://github.com/steveire/grantlee"
+SRC_URI="http://downloads.grantlee.org/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="debug doc test"
+
+BDEPEND="
+	doc? ( app-doc/doxygen[dot] )
+	test? ( dev-qt/linguist-tools:5 )
+"
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+
+RESTRICT+=" !test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.3.0-nonfatal-warnings.patch"
+	"${FILESDIR}/${P}-slot.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	use doc && cmake_src_compile docs
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_install() {
+	use doc && local HTML_DOCS=("${BUILD_DIR}/apidox/")
+
+	cmake_src_install
+}
-- 
cgit v1.2.3