From 9368ace94caa5cdda868a0dbb7c75a3fc7a2b911 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 22 Aug 2023 21:47:11 +0100
Subject: gentoo auto-resync : 22:08:2023 - 21:47:11

---
 dev-libs/libei/Manifest           |  4 ++
 dev-libs/libei/libei-1.0.0.ebuild | 98 +++++++++++++++++++++++++++++++++++++++
 dev-libs/libei/metadata.xml       | 11 +++++
 3 files changed, 113 insertions(+)
 create mode 100644 dev-libs/libei/Manifest
 create mode 100644 dev-libs/libei/libei-1.0.0.ebuild
 create mode 100644 dev-libs/libei/metadata.xml

(limited to 'dev-libs/libei')

diff --git a/dev-libs/libei/Manifest b/dev-libs/libei/Manifest
new file mode 100644
index 000000000000..ce8a2facd596
--- /dev/null
+++ b/dev-libs/libei/Manifest
@@ -0,0 +1,4 @@
+DIST libei-1.0.0.tar.bz2 166254 BLAKE2B 72f9e0426b87e81061e8b01356cfc67897f46219be74c6b7309d2f7b26ea4f6b716ab33a2f9ec16daa0bc555359535b589219eddceced9fa636a2964d32c3d7d SHA512 145b514782fb500bed09437200d0fb989aa0a2cd81d1752938f9b4819ae8130510b2a4a65231bacb8565fcddaa1ffd1925c84cd3a5d34eaa4918ec05105465f6
+DIST munit-fbbdf1467eb0d04a6ee465def2e529e4c87f2118.tar.gz 27724 BLAKE2B 9670c9b7a0b5d9ee6ec8df2dea9e241b043964ecf1fa3f6060ad1d16c40ab6afe47f53c6d4a791003e101a0b363263b858e6e4e445f868292753dd1ee7f7e3ce SHA512 26b5599fd12be627a692823ebf496fa446be7ed04a1233fb42e0667c05109b0f804f76646e289ac660fc815baf45f77ec8caf0ff2ea7fb0b4f87f0038a2b971c
+EBUILD libei-1.0.0.ebuild 2331 BLAKE2B 386b510084d9d4c953fde32216f48dc0371b7aa3be900e892cd37b1d12d23a9cd9ffd62d4729370674c91febc5c6cd6a7e9811871f8a2df111f1fb5f176b4ca3 SHA512 4d85cece4a9594f284ef833959dd0f750fb5d020e80c00d57a326588e2b78e74bffdf9c332e961724d067eebb8926bcbb71afa0ce4a6f516b8d1132bb4d1a606
+MISC metadata.xml 336 BLAKE2B 2fd4200876fa044f3563b0eea2096214af92fed1a8db009cf4885a7cf32f303b0a6911dba18cc8fac942348dbe2668ea2d50fabedd235e33be0793076ab0e5be SHA512 a26feb7d41edc6f728bfbaf805cfefa6bba4c5161e70785e7de5f389492f405f7cd6f2c55cce1d2c6bdf9af3aba17e1e51254d9e4421c4fab2e61f2c563c8f3f
diff --git a/dev-libs/libei/libei-1.0.0.ebuild b/dev-libs/libei/libei-1.0.0.ebuild
new file mode 100644
index 000000000000..227b825ec103
--- /dev/null
+++ b/dev-libs/libei/libei-1.0.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit meson python-any-r1
+
+DESCRIPTION="Library for Emulated Input, primarily aimed at the Wayland stack"
+HOMEPAGE="https://gitlab.freedesktop.org/libinput/libei"
+SRC_URI="https://gitlab.freedesktop.org/libinput/${PN}/-/archive/${PV}/${P}.tar.bz2"
+MUNIT_COMMIT="fbbdf1467eb0d04a6ee465def2e529e4c87f2118"
+SRC_URI+=" https://github.com/nemequ/munit/archive/${MUNIT_COMMIT}.tar.gz -> munit-${MUNIT_COMMIT}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="elogind systemd test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/libevdev-1.9.902
+	|| (
+		systemd? ( >=sys-apps/systemd-237 )
+		elogind? ( >=sys-auth/elogind-237 )
+		sys-libs/basu
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/attrs[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+	')
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+			dev-python/pyyaml[${PYTHON_USEDEP}]
+			dev-python/structlog[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		python_has_version \
+			"dev-python/pytest[${PYTHON_USEDEP}]" \
+			"dev-python/python-dbusmock[${PYTHON_USEDEP}]" \
+			"dev-python/pyyaml[${PYTHON_USEDEP}]" \
+			"dev-python/structlog[${PYTHON_USEDEP}]" \
+			|| return 1
+	fi
+	python_has_version \
+		"dev-python/attrs[${PYTHON_USEDEP}]" \
+		"dev-python/jinja[${PYTHON_USEDEP}]" \
+		|| return 1
+}
+
+src_unpack() {
+	if [[ -n ${A} ]]; then
+		unpack ${A}
+		mv "${WORKDIR}"/munit-${MUNIT_COMMIT} "${WORKDIR}"/${P}/subprojects/munit || die
+		rm "${WORKDIR}"/${P}/subprojects/munit.wrap || die
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed -i -e 's:^valgrind = .*:valgrind = disabler():g' test/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddocumentation=""
+		-Dliboeffis=enabled
+		$(meson_feature test tests)
+	)
+	if use systemd; then
+		emesonargs+=(-Dsd-bus-provider=libsystemd)
+	elif use elogind; then
+		emesonargs+=(-Dsd-bus-provider=libelogind)
+	else
+		emesonargs+=(-Dsd-bus-provider=basu)
+	fi
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# munit subproject is installed but not wanted
+	if use test; then
+		rm "${ED}"/usr/lib*/libmunit.so || die
+	fi
+}
diff --git a/dev-libs/libei/metadata.xml b/dev-libs/libei/metadata.xml
new file mode 100644
index 000000000000..4e1ad47f523f
--- /dev/null
+++ b/dev-libs/libei/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>x11@gentoo.org</email>
+    <name>X11</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="freedesktop-gitlab">libinput/libei</remote-id>
+  </upstream>
+</pkgmetadata>
-- 
cgit v1.2.3