From feb0daf81d888e9160f9f94502de09b66f2a63fd Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 21 Jun 2020 17:50:24 +0100
Subject: gentoo resync : 21.06.2020

---
 dev-libs/libzip/Manifest            |   2 +
 dev-libs/libzip/libzip-1.7.1.ebuild | 112 ++++++++++++++++++++++++++++++++++++
 2 files changed, 114 insertions(+)
 create mode 100644 dev-libs/libzip/libzip-1.7.1.ebuild

(limited to 'dev-libs/libzip')

diff --git a/dev-libs/libzip/Manifest b/dev-libs/libzip/Manifest
index 4ed219cd6ebb..dfec52b04e32 100644
--- a/dev-libs/libzip/Manifest
+++ b/dev-libs/libzip/Manifest
@@ -1,5 +1,7 @@
 DIST libzip-1.6.1.tar.xz 732932 BLAKE2B 6f63ecb56767b730e5c5639c01e3e050ed64d1c1508b11d4cd1c75e2834988e14140a5e49ba25454d77c40c59b101615a9e00823066a35eaca0519147a75f5e6 SHA512 dcf3790933c95f66bdcbdb276497b36e57776103b0b1064a94479e84eaa0a09df8dd91509cb4ccab3a6724f0650f076ca1e332d73acc94b653e99a3e94a64574
 DIST libzip-1.7.0.tar.xz 737184 BLAKE2B 4442925b77ad336793ecc891e2c096c8b98457d193a5ebda239462ef5120b3e041b1882d56dc0c4c94d0f3c00e5117d04964af0a8827230f0dbf937a8b07a5fa SHA512 9c1632b4e0b4cfe22c5670d815bc8893d540226e3e64cf8cce7039a90bdc7048dedadb4804b151291e312c97bb384bd671e43021401c4c3e33a4e597972bc681
+DIST libzip-1.7.1.tar.xz 737496 BLAKE2B bd4c73bf317fa767ff0ea3c10b7f2e96699dc7ed7bd05fdaf3c5d477cd42aa18b40627569498697be1b5360d43471a9b8132909781f8bd32bda6f46534e4a61b SHA512 e924749274e5e45b83ba4bc961bfd299b9dd05829c1f42880a9814f942dbf7afe79aa1ea4e2b33d6db1dba1f7f948c0de40517f2ef90cc8725650b8cb88d9a14
 EBUILD libzip-1.6.1-r1.ebuild 2288 BLAKE2B ac0aa25a70174fe99977e49f70beb4876a221e884411bc69fe8a4a570a9a207a2ca578c0064a1c22ea101cb8aab0e86907df5b629f2509230984cacd14aa4814 SHA512 2412dddca1bcbc6d3c5ab7550980f132ceec5d56bdcb3875a27feb539a3c648f522766fd68663d289ebfd41b8d31477751378b0e8c4371c08b437e9036f6fd71
 EBUILD libzip-1.7.0.ebuild 2353 BLAKE2B 4a01907cd29bf76e40ee13fa8c6226179cb79f51593c46307f0daba1ef171d7be315d217fe7042c791b1fbf59fcf6115417b980f95d849ef74641d3d64236343 SHA512 6c8784276e8e16b9c0a6c732aaf445cc2be74628f818e5cdf50b8135bdd01f195cf62633aa3fc5259ed8b8b615dac2c457c110ef58c48bd38e1e915cda742cef
+EBUILD libzip-1.7.1.ebuild 2353 BLAKE2B 4a01907cd29bf76e40ee13fa8c6226179cb79f51593c46307f0daba1ef171d7be315d217fe7042c791b1fbf59fcf6115417b980f95d849ef74641d3d64236343 SHA512 6c8784276e8e16b9c0a6c732aaf445cc2be74628f818e5cdf50b8135bdd01f195cf62633aa3fc5259ed8b8b615dac2c457c110ef58c48bd38e1e915cda742cef
 MISC metadata.xml 509 BLAKE2B e5012e29cc2157f4cd37b19edbdd2da53377f2671574681aff241dcab50e22d39b8db7bce14b7085cf39e4adbe89c486047f3089a9f91fde3411b02de45c8284 SHA512 bfa09ea8c47388786ec4fa938fbb2df96c4d2bf936f1a2a79765bc178ac34a9d69c19a1be53eef743d49548e32ce110f3e4b9776932248624192d4b92b7525f8
diff --git a/dev-libs/libzip/libzip-1.7.1.ebuild b/dev-libs/libzip/libzip-1.7.1.ebuild
new file mode 100644
index 000000000000..8edc5a80ac6e
--- /dev/null
+++ b/dev-libs/libzip/libzip-1.7.1.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake multibuild
+
+DESCRIPTION="Library for manipulating zip archives"
+HOMEPAGE="https://nih.at/libzip/"
+SRC_URI="https://www.nih.at/libzip/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+IUSE="bzip2 gnutls libressl lzma mbedtls ssl static-libs test tools"
+REQUIRED_USE="test? ( tools )"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2:= )
+	lzma? ( app-arch/xz-utils )
+	ssl? (
+		gnutls? (
+			dev-libs/nettle:0=
+			>=net-libs/gnutls-3.6.5:=
+		)
+		!gnutls? (
+			mbedtls? ( net-libs/mbedtls:= )
+			!mbedtls? (
+				!libressl? ( dev-libs/openssl:0= )
+				libressl? ( dev-libs/libressl:0= )
+			)
+		)
+	)
+"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	# Upstream doesn't support building dynamic & static
+	# simultaneously: https://github.com/nih-at/libzip/issues/76
+	MULTIBUILD_VARIANTS=( shared $(usev static-libs) )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DBUILD_EXAMPLES=OFF # nothing is installed
+			-DENABLE_COMMONCRYPTO=OFF # not in tree
+			-DENABLE_BZIP2=$(usex bzip2)
+			-DENABLE_LZMA=$(usex lzma)
+		)
+		if [[ ${MULTIBUILD_VARIANT} = static-libs ]]; then
+			mycmakeargs+=(
+				-DBUILD_DOC=OFF
+				-DBUILD_EXAMPLES=OFF
+				-DBUILD_SHARED_LIBS=OFF
+				-DBUILD_TOOLS=OFF
+			)
+		else
+			mycmakeargs+=(
+				-DBUILD_DOC=ON
+				-DBUILD_REGRESS=$(usex test)
+				-DBUILD_TOOLS=$(usex tools)
+			)
+		fi
+
+		if use ssl; then
+			if use gnutls; then
+				mycmakeargs+=(
+					-DENABLE_GNUTLS=$(usex gnutls)
+					-DENABLE_MBEDTLS=OFF
+					-DENABLE_OPENSSL=OFF
+				)
+			elif use mbedtls; then
+				mycmakeargs+=(
+					-DENABLE_GNUTLS=OFF
+					-DENABLE_MBEDTLS=$(usex mbedtls)
+					-DENABLE_OPENSSL=OFF
+				)
+			else
+				mycmakeargs+=(
+					-DENABLE_GNUTLS=OFF
+					-DENABLE_MBEDTLS=OFF
+					-DENABLE_OPENSSL=ON
+				)
+			fi
+		else
+			mycmakeargs+=(
+				-DENABLE_GNUTLS=OFF
+				-DENABLE_MBEDTLS=OFF
+				-DENABLE_OPENSSL=OFF
+			)
+		fi
+		cmake_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+}
+
+src_test() {
+	[[ ${MULTIBUILD_VARIANT} = shared ]] && cmake_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant cmake_src_install
+}
-- 
cgit v1.2.3