From 4583148f2657a7a66fd68b25c9fab02be110c989 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 24 Dec 2022 02:00:51 +0000
Subject: gentoo auto-resync : 24:12:2022 - 02:00:50

---
 dev-libs/link-grammar/Manifest                   |   2 +
 dev-libs/link-grammar/link-grammar-5.12.0.ebuild | 109 +++++++++++++++++++++++
 2 files changed, 111 insertions(+)
 create mode 100644 dev-libs/link-grammar/link-grammar-5.12.0.ebuild

(limited to 'dev-libs/link-grammar')

diff --git a/dev-libs/link-grammar/Manifest b/dev-libs/link-grammar/Manifest
index 28f810088137..9fbba2f86af3 100644
--- a/dev-libs/link-grammar/Manifest
+++ b/dev-libs/link-grammar/Manifest
@@ -1,3 +1,5 @@
 DIST link-grammar-5.11.0.tar.gz 4672430 BLAKE2B 35892e05805a83ebbd700611d19aaa9ad1ede4ba3baf60c85ef8e5abbc40134fcb71d9cb9f41518f663c60ad11aac7bd0b316c8c95a12631032f5ad79564d686 SHA512 6a24bc8d5c9f0dd63460c092fc46880503018e949aa277148f8f551d6cc9d929d3a981eeaba00afc6e618c1e4505438d0c7e9a57dfe7a8deb7d3a8f183c56636
+DIST link-grammar-5.12.0.tar.gz 4688144 BLAKE2B 3ab74bcd23118c1d933895ac5ac8f042448f173234db1528de496e2f4aa88cd9b96d4783e54584f05d8af5bb835fee1f62f039ed883e2b24511198526d334dbd SHA512 1938e53a2d8bdb5d0c352e9bb7108b280d3c4da890f540f41bdc257eea1ea6de5712f99602fc0f4187654540e1142b5216efb2a8c9957f32ce0dec86d85ec3cb
 EBUILD link-grammar-5.11.0.ebuild 2784 BLAKE2B 23746087d6c3ac93ca90cf5061e3d88abb4e4b6eeca01c6db433d69a2eca7258237b11f9acb14fa00b7b40a71252e66e58fa8f253368ffe7bff895a87a800949 SHA512 5e7e44e2bc9856b8df68894eac5f8cd4b3f781b59bf4f1a0a909c20cfb0ca7aec6292c951aa651cf3f0c5d2bab3e6b4a36d02799f1155e7e9abeb4091dc09e03
+EBUILD link-grammar-5.12.0.ebuild 2786 BLAKE2B aba4bb5d25ff692040528e6d3c299fb3cbabd3857ae84a605a7e5ff9d29414253368f336b0a5eb49b751e254b28b2b0362672f0cf53bcb16ad37904cba6ffba1 SHA512 f6affa26a059080331f89664521b9d963a56d61a779d8ca2df96a04c814c5ee5768108fd66d2ad050975f144b2b35e7ac1c79abaa9242dd7c5b3c8f082e6934e
 MISC metadata.xml 1197 BLAKE2B fac6dd40856d97100ee06cdcd340e660bb2ffe527df31983165beec9d194839336dfddb54be33561560ac2c79d8bad12809eef53abd4059b7c74b7494d728354 SHA512 dcb16b8afa977639e3fe8633762fc7a26d8ab095da15d630bedc6ba65e4c82ec5f0bedbd564b6ad0490790723c0a04065a5cab536aff93cdcf8eab5f1a2d503e
diff --git a/dev-libs/link-grammar/link-grammar-5.12.0.ebuild b/dev-libs/link-grammar/link-grammar-5.12.0.ebuild
new file mode 100644
index 000000000000..ed4f65314cd3
--- /dev/null
+++ b/dev-libs/link-grammar/link-grammar-5.12.0.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit autotools python-r1 out-of-source
+
+DESCRIPTION="A Syntactic English parser"
+HOMEPAGE="https://www.abisource.com/projects/link-grammar/ https://www.link.cs.cmu.edu/link/"
+SRC_URI="https://www.abisource.com/downloads/${PN}/${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="aspell +hunspell python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# XXX: sqlite is automagic
+# Does not build with >=sci-mathematics/minisat-2, bug #593662
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/libpcre2:=
+	aspell? ( app-text/aspell )
+	hunspell? ( app-text/hunspell )
+	python? ( ${PYTHON_DEPS} )
+	!sci-mathematics/minisat"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/swig:0
+	sys-devel/autoconf-archive
+	virtual/pkgconfig"
+
+pkg_setup() {
+	if use aspell && use hunspell; then
+		ewarn "You have enabled 'aspell' and 'hunspell' support, but both cannot coexist,"
+		ewarn "only hunspell will be built. Press Ctrl+C and set only 'aspell' USE flag if"
+		ewarn "you want aspell support."
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+my_src_configure() {
+	local myconf=(
+		--disable-maintainer-mode
+		--disable-editline
+		# java is hopelessly broken, invokes maven at build time (bug #806157)
+		--disable-java-bindings
+		--disable-perl-bindings
+		--enable-sat-solver=bundled
+		--with-regexlib=pcre2
+		$(use_enable aspell)
+		$(use_enable hunspell)
+		$(usev hunspell --with-hunspell-dictdir="${EPREFIX}"/usr/share/myspell)
+	)
+
+	econf \
+		--disable-python-bindings \
+		"${myconf[@]}"
+
+	if use python; then
+		python_configure() {
+			econf \
+				--enable-python-bindings \
+				"${myconf[@]}"
+		}
+		python_foreach_impl run_in_build_dir python_configure
+	fi
+}
+
+my_src_compile() {
+	local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+	default
+
+	if use python; then
+		python_compile() {
+			emake -C bindings/python \
+				VPATH="${S}:${MAIN_BUILD_DIR}" \
+				_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+				_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
+		}
+		python_foreach_impl run_in_build_dir python_compile
+	fi
+}
+
+my_src_install() {
+	local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+	default
+
+	if use python; then
+		python_install() {
+			emake -C bindings/python \
+				VPATH="${S}:${MAIN_BUILD_DIR}" \
+				_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+				_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+				DESTDIR="${D}" \
+				install
+		}
+		python_foreach_impl run_in_build_dir python_install
+	fi
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3