From d72a987a342949e200b5e9decbd71f246da53788 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 12 May 2024 00:01:15 +0100
Subject: gentoo auto-resync : 12:05:2024 - 00:01:15

---
 dev-libs/link-grammar/Manifest                   |   2 +
 dev-libs/link-grammar/link-grammar-5.12.4.ebuild | 113 +++++++++++++++++++++++
 2 files changed, 115 insertions(+)
 create mode 100644 dev-libs/link-grammar/link-grammar-5.12.4.ebuild

(limited to 'dev-libs/link-grammar')

diff --git a/dev-libs/link-grammar/Manifest b/dev-libs/link-grammar/Manifest
index 9e2295901cd9..1919e33961c3 100644
--- a/dev-libs/link-grammar/Manifest
+++ b/dev-libs/link-grammar/Manifest
@@ -1,4 +1,6 @@
 AUX link-grammar-5.12.3-Wimplicit-function-declaration.patch 1295 BLAKE2B 90ece06844dee100de78b45d172bc2a3bef9b2625f47dfb4f1d5a832f010defb28b9e7d8442d8c4e7f0ea01c246200b41629976891a761217624413c80ff2c41 SHA512 b878d6e64e45c40470b61aa31f3c7ceeef3946e1fd15a0f473a131c0cc11e44f1ac7bbfc602362c05659416e40c706d25f1be7e01204b5b9b7b58f71902de2e1
 DIST link-grammar-5.12.3.tar.gz 4704751 BLAKE2B a7f0fe39c51ed26ea764d583b38b21cfce6e596c6cd94db6ba47b3606a2b6cd9e56bd6fedeb104dbb345baedae3e144af96999739dda9daa9a9e5886bd98d2f4 SHA512 e0fdb78ec03042119011afea005a62829317fd0bc20afcd94e3f234c9c5252ed9c57d717b75368ac4a63dd8493bd86f551870299925f3b9b95b11915f48d8abe
+DIST link-grammar-5.12.4.tar.gz 4720724 BLAKE2B 6573895298128165d7f840a13aad124418dbd1b9c70436dbe2bd65b3fd1883777e72da13f5196031696edb7cdc6c9d86acd5fdd4d1aa8fb295a136b2ba0568cf SHA512 fd5318c21202c17902de996882fd8630c7e95622b8ebe6877a334df22ff678a6040e0519bdabfa1138aaefdf3a7c20cbfe9e65bdce4dfe568729c9ba5a2d6fe5
 EBUILD link-grammar-5.12.3.ebuild 2965 BLAKE2B 038477eb61c4ad170de17f2be8ea8bd69ba64e7d594a3382de5d7861a6503fec2ac56a8e9aac345d66cf25ede71e8d6b0137fd7839fe949c254603f5ae6d439e SHA512 71dffd2543d5ad7e26059785dc78178a1c377c4ebd33eaa9c53f7cb82530ac14b136942b7c24e2098149c72646f252fe82b058f34604b4f41a7245daa04424e2
+EBUILD link-grammar-5.12.4.ebuild 2838 BLAKE2B 2c1b448bbc7499726c4a8193b1866d012bc7557ac1e9702d3b209a07814e789c54374def028259c567037da8c0c3dc116c35355c96cfdf496a031dc5f2a13f64 SHA512 29e50f41a1b3947a9d80498ebcae0d73d86ac2d96b03837f59b8ac81ff1114bfc9510c239ca9f4cbf6da03c8c051717513ab2f5a770c8a0da66a3f96d3127d5f
 MISC metadata.xml 1197 BLAKE2B fac6dd40856d97100ee06cdcd340e660bb2ffe527df31983165beec9d194839336dfddb54be33561560ac2c79d8bad12809eef53abd4059b7c74b7494d728354 SHA512 dcb16b8afa977639e3fe8633762fc7a26d8ab095da15d630bedc6ba65e4c82ec5f0bedbd564b6ad0490790723c0a04065a5cab536aff93cdcf8eab5f1a2d503e
diff --git a/dev-libs/link-grammar/link-grammar-5.12.4.ebuild b/dev-libs/link-grammar/link-grammar-5.12.4.ebuild
new file mode 100644
index 000000000000..b6ed517ee9e9
--- /dev/null
+++ b/dev-libs/link-grammar/link-grammar-5.12.4.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit autotools python-r1 out-of-source
+
+DESCRIPTION="A Syntactic English parser"
+HOMEPAGE="https://www.abisource.com/projects/link-grammar/ https://www.link.cs.cmu.edu/link/"
+SRC_URI="https://www.gnucash.org/link-grammar/downloads/${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="aspell +hunspell python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# XXX: sqlite is automagic
+# Does not build with >=sci-mathematics/minisat-2, bug #593662
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/libpcre2:=
+	aspell? ( app-text/aspell )
+	hunspell? ( app-text/hunspell )
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/swig:0
+	dev-build/autoconf-archive
+	virtual/pkgconfig"
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	# _AC_UNDECLARED_BUILTIN false positive
+	strchr
+)
+
+pkg_setup() {
+	if use aspell && use hunspell; then
+		ewarn "You have enabled 'aspell' and 'hunspell' support, but both cannot coexist,"
+		ewarn "only hunspell will be built. Press Ctrl+C and set only 'aspell' USE flag if"
+		ewarn "you want aspell support."
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+my_src_configure() {
+	local myconf=(
+		--disable-maintainer-mode
+		--disable-editline
+		# java is hopelessly broken, invokes maven at build time (bug #806157)
+		--disable-java-bindings
+		--disable-perl-bindings
+		--disable-sat-solver
+		--with-regexlib=pcre2
+		$(use_enable aspell)
+		$(use_enable hunspell)
+		$(usev hunspell --with-hunspell-dictdir="${EPREFIX}"/usr/share/myspell)
+	)
+
+	econf \
+		--disable-python-bindings \
+		"${myconf[@]}"
+
+	if use python; then
+		python_configure() {
+			econf \
+				--enable-python-bindings \
+				"${myconf[@]}"
+		}
+		python_foreach_impl run_in_build_dir python_configure
+	fi
+}
+
+my_src_compile() {
+	local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+	default
+
+	if use python; then
+		python_compile() {
+			emake -C bindings/python \
+				VPATH="${S}:${MAIN_BUILD_DIR}" \
+				_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+				_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
+		}
+		python_foreach_impl run_in_build_dir python_compile
+	fi
+}
+
+my_src_install() {
+	local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+	default
+
+	if use python; then
+		python_install() {
+			emake -C bindings/python \
+				VPATH="${S}:${MAIN_BUILD_DIR}" \
+				_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+				_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+				DESTDIR="${D}" \
+				install
+		}
+		python_foreach_impl run_in_build_dir python_install
+	fi
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3