From 13b130894803eda558b74353eda3bf7504615b38 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 4 Jun 2023 09:34:05 +0100
Subject: gentoo auto-resync : 04:06:2023 - 09:34:05

---
 dev-python/docker/Manifest            |  3 ++
 dev-python/docker/docker-6.1.2.ebuild | 56 +++++++++++++++++++++++++++++++++++
 dev-python/docker/metadata.xml        | 13 ++++++++
 3 files changed, 72 insertions(+)
 create mode 100644 dev-python/docker/Manifest
 create mode 100644 dev-python/docker/docker-6.1.2.ebuild
 create mode 100644 dev-python/docker/metadata.xml

(limited to 'dev-python/docker')

diff --git a/dev-python/docker/Manifest b/dev-python/docker/Manifest
new file mode 100644
index 000000000000..8d153c2ea871
--- /dev/null
+++ b/dev-python/docker/Manifest
@@ -0,0 +1,3 @@
+DIST docker-py-6.1.2.gh.tar.gz 253183 BLAKE2B 28435f5db00cbcd189cb06af77a4eac95a27944d324718c02b1d8f28c9954242c3a36ae376b0e0118ce1e03cb49f44925250b33b34b3ba5b459ef0df9ae9a6a4 SHA512 13c2711c44ae7b781187abaa7518ed86dd37192a44b6fff2c0090bfd8edb82555d15fb9d1681de9db47839f8dbcf17cc03fb88ed4e0e0052032dbcc9ed4c0078
+EBUILD docker-6.1.2.ebuild 1226 BLAKE2B 99c8eb2a1cf05e3238b2491ec767b1cf733c5ade0b01635b30545240ec30e939c14d3f141855d795da76fe4553141c8c0bd4255df639f07a7362ed491929843a SHA512 872e589e6acc51d3e0e07054c0c9e9a578e8b0e836b0a9c24f5433111aba71e806705331decb9624242945788a7bbbe0e2d9c8761675cb3ffd32076eb9c9cee0
+MISC metadata.xml 432 BLAKE2B d57abab67aa69fa94d65ad06263fd9aa748e9c918d51750b613b6a22fffbd3642c8b1e01ebf521edff10d082c9e41329b3234b981283e3ca8bb07ddee7f97dd5 SHA512 b7d9c322623a2e68902def06d10d8f2a3c18d231a36383b52f80001ef2a2161633a66950afd7ad60f07e5d666d15d1fab738e46fce42ab221ad2e1e0b2fb600a
diff --git a/dev-python/docker/docker-6.1.2.ebuild b/dev-python/docker/docker-6.1.2.ebuild
new file mode 100644
index 000000000000..2e969b8180d1
--- /dev/null
+++ b/dev-python/docker/docker-6.1.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+MY_P=docker-py-${PV}
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="
+	https://github.com/docker/docker-py/
+	https://pypi.org/project/docker/
+"
+SRC_URI="
+	https://github.com/docker/docker-py/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
+
+RDEPEND="
+	>=dev-python/packaging-14.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/paramiko-2.4.3[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/myst-parser'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# localhost has a better chance of being in /etc/hosts
+	sed -e 's:socket[.]gethostname():"localhost":' \
+		-i tests/unit/api_test.py || die
+
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	epytest tests/unit
+}
diff --git a/dev-python/docker/metadata.xml b/dev-python/docker/metadata.xml
new file mode 100644
index 000000000000..f7c364e174f0
--- /dev/null
+++ b/dev-python/docker/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">docker/docker-py</remote-id>
+		<bugs-to>https://github.com/docker/docker-py/issues</bugs-to>
+		<remote-id type="pypi">docker</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3