From e23cdda4dbb0c83b9e682ab5e916085a35203da5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 23 Jun 2018 07:00:28 +0100
Subject: gentoo resync : 23.06.2018

---
 .../flask-babel/flask-babel-0.11.2-r1.ebuild       | 48 ++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-python/flask-babel/flask-babel-0.11.2-r1.ebuild

(limited to 'dev-python/flask-babel/flask-babel-0.11.2-r1.ebuild')

diff --git a/dev-python/flask-babel/flask-babel-0.11.2-r1.ebuild b/dev-python/flask-babel/flask-babel-0.11.2-r1.ebuild
new file mode 100644
index 000000000000..beb8626524a0
--- /dev/null
+++ b/dev-python/flask-babel/flask-babel-0.11.2-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN="Flask-Babel"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="i18n and l10n support for Flask based on Babel and pytz"
+HOMEPAGE="https://pythonhosted.org/Flask-Babel/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.5[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed -i -e "s/'sphinx.ext.intersphinx'//" \
+		-e '/^html_theme =/,/^}/d' docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	nosetests || die "Tests failed under ${EPYTHON}"
+}
-- 
cgit v1.2.3