From 3faa6ebe0068b432ee5a9390c47ceca068ea7fe9 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 21 Mar 2024 07:00:13 +0000
Subject: gentoo auto-resync : 21:03:2024 - 07:00:13

---
 .../importlib-metadata-7.1.0.ebuild                | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-python/importlib-metadata/importlib-metadata-7.1.0.ebuild

(limited to 'dev-python/importlib-metadata/importlib-metadata-7.1.0.ebuild')

diff --git a/dev-python/importlib-metadata/importlib-metadata-7.1.0.ebuild b/dev-python/importlib-metadata/importlib-metadata-7.1.0.ebuild
new file mode 100644
index 000000000000..45aa526ce45d
--- /dev/null
+++ b/dev-python/importlib-metadata/importlib-metadata-7.1.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+# NB: this package extends beyond built-in importlib stuff in py3.8+
+# new entry_point API not yet included in cpython release
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Read metadata from Python packages"
+HOMEPAGE="
+	https://github.com/python/importlib_metadata/
+	https://pypi.org/project/importlib-metadata/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/jaraco-test-5.4[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "importlib_metadata"
+		version = "${PV}"
+		description = "Read metadata from Python packages"
+	EOF
+}
-- 
cgit v1.2.3