From d99093fb4bb5652015c06274d64083daa2439e4f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 3 Mar 2021 10:28:17 +0000
Subject: gentoo resync : 03.03.2021

---
 dev-python/ipython/Manifest              |   2 +
 dev-python/ipython/ipython-7.21.0.ebuild | 137 +++++++++++++++++++++++++++++++
 2 files changed, 139 insertions(+)
 create mode 100644 dev-python/ipython/ipython-7.21.0.ebuild

(limited to 'dev-python/ipython')

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index ffc2e46447f3..c9636b3a0563 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,6 +1,8 @@
 AUX 2.1.0-substitute-files.patch 1017 BLAKE2B 70577eb950a18345804a2a4b750bd233dc6a0b6bbdb524dfc66e0f4a7c69b0eeb2d35efb9d1845d567a11d1afa7881068b4757e42b9baf24dc01ba3026608a38 SHA512 fc4c9e12267ac5f04a2e16ad27334a093638538b8149ff380099fcbeb674a276ab9eb624a508010e37f82c05d5f7ab527a80e386b3e7b61c123ecb8effd9d542
 DIST ipython-7.19.0.tar.gz 5225775 BLAKE2B 1909d8336e7fc90959da4ca33ad7edcb8c2dec0a5aa20ca6f643ef53482fe7bf0d52e2bbec7cf97e72a1fd4d37af45ba01166febb25f35b52d69ffc062f0f0e8 SHA512 5350a125da3050acaea4899939a3b9d779009a2f5769fc9f3aa514ce029df050069ef9310d3255ad62f28912b4dec39207267248d3a2c3e9131cffd691322622
 DIST ipython-7.20.0.tar.gz 5140776 BLAKE2B ec01caf874ab9c331eb1f074f9e70acb521fe6d4abe3e8f086d9e9e77cd710c3b0d88c6d7b071abc6962eee8141b65a012ec772cbec3450db25f086fc66cf1c6 SHA512 2fff1a64c3d83e794e76bcbdf54e105f499321d9a7e5d3221cdc3e15a96e90543fd465b8dbee4836965286e7c1f1ea6d13e4d3d88c095164858bf71c161111fe
+DIST ipython-7.21.0.tar.gz 5141725 BLAKE2B dae44d481e959ef7d002bdb51d0ab1e2f3eca3449071a2e4161aa735c06fef8a948d80bafd3f2bdd066208437b5ed36615cad5885af453771a32a313fba907eb SHA512 200e41d4e06343b6320f3d106925f6c995f39cf88d01250f53885d4e94d0fd9454a6be4cd7c69410f7dced94b05634f6d2269f9737cc563accf85206d4d7fff8
 EBUILD ipython-7.19.0-r1.ebuild 3703 BLAKE2B efb9a0572c9368abfee6b103dd44517a5700fa1a33cb00e07f61bd286dce2de9a11eb16fefd6bec121871bc6504ed3be2aa2109efe1114442cd4c0a3620bd73a SHA512 8c7c1260c7b07e09282e01090033e702a5fb118c56e0e091a265c5a3bfe5129a17f702cd6ff30a1fef6bf732a678bf1efac4273f7088a2262f8c39202e6fd19c
 EBUILD ipython-7.20.0.ebuild 3708 BLAKE2B a1423f8a27cf4e4f404c1944182b667eba23abfbb947e32c73d0764934b63282dd05c016db5794378bc3a5e34911474520a28709c3ef162fdc16d19f807c0346 SHA512 2d482219964bc6d1b29209bdc1d0377fed71e4258cd7dd912958d40d014eb10ae012c07eb4db28f9392d9a8c7696125d2de22fe454f2d1cdcd41c0c60f22bf7b
+EBUILD ipython-7.21.0.ebuild 3708 BLAKE2B a1423f8a27cf4e4f404c1944182b667eba23abfbb947e32c73d0764934b63282dd05c016db5794378bc3a5e34911474520a28709c3ef162fdc16d19f807c0346 SHA512 2d482219964bc6d1b29209bdc1d0377fed71e4258cd7dd912958d40d014eb10ae012c07eb4db28f9392d9a8c7696125d2de22fe454f2d1cdcd41c0c60f22bf7b
 MISC metadata.xml 2882 BLAKE2B 189477b4ccde9051b61d2a4ff5134907886795f97c5201fc2bf9c012526333151931a1445b6315f286474b71af84253033cbe9bf89bffa7813bfa49a4a07ef6c SHA512 f54fef4552d09a03a8d186c45f917c091928f1de84dfbdd80f1db80912d616d509f10c588de533916d9c494f5b3ca5e6e50a6d8b8c59ea47781311ad4319442a
diff --git a/dev-python/ipython/ipython-7.21.0.ebuild b/dev-python/ipython/ipython-7.21.0.ebuild
new file mode 100644
index 000000000000..e314d1de9986
--- /dev/null
+++ b/dev-python/ipython/ipython-7.21.0.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${CDEPEND}
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+
+BDEPEND="
+	test? (
+		${CDEPEND}
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.14[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)"
+
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	distutils_install_for_testing
+	pushd "${TEST_DIR}" >/dev/null || die
+	"${TEST_DIR}"/scripts/iptest || die
+	popd >/dev/null || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}
-- 
cgit v1.2.3