From 552fc3ba95eab5c2c1a8b2b55ab432a1019739a0 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 30 Jan 2023 08:57:14 +0000
Subject: gentoo auto-resync : 30:01:2023 - 08:57:13

---
 dev-python/libtmux/libtmux-0.21.0.ebuild | 56 ++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-python/libtmux/libtmux-0.21.0.ebuild

(limited to 'dev-python/libtmux/libtmux-0.21.0.ebuild')

diff --git a/dev-python/libtmux/libtmux-0.21.0.ebuild b/dev-python/libtmux/libtmux-0.21.0.ebuild
new file mode 100644
index 000000000000..499498389f30
--- /dev/null
+++ b/dev-python/libtmux/libtmux-0.21.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python API for tmux"
+HOMEPAGE="
+	https://libtmux.git-pull.com/
+	https://github.com/tmux-python/libtmux/
+	https://pypi.org/project/libtmux/
+"
+SRC_URI="
+	https://github.com/tmux-python/libtmux/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=app-misc/tmux-3.0a
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/twine[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	libtmux/pane.py::libtmux.pane.Pane.send_keys
+)
+
+python_prepare_all() {
+	local issues="https://github.com/tmux-python/libtmux/issues/"
+	sed -r -i "s|:issue:\`([[:digit:]]+)\`|\`issue \1 ${issues}\1\`|" CHANGES || die
+	rm requirements/doc.txt || die
+
+	# increase timeouts for tests
+	sed -e 's/0.01/0.1/' -i tests/test_test.py || die
+
+	sed -e '/addopts/s:--doctest-docutils-modules::' \
+		-e '/README\.md/d' \
+		-i setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
-- 
cgit v1.2.3