From a6611f9bc959724ec73dbaa6f1c608698c387a8c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 10 Nov 2023 16:37:59 +0000
Subject: gentoo auto-resync : 10:11:2023 - 16:37:59

---
 dev-python/oct2py/oct2py-5.6.0.ebuild | 54 +++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 dev-python/oct2py/oct2py-5.6.0.ebuild

(limited to 'dev-python/oct2py/oct2py-5.6.0.ebuild')

diff --git a/dev-python/oct2py/oct2py-5.6.0.ebuild b/dev-python/oct2py/oct2py-5.6.0.ebuild
new file mode 100644
index 000000000000..ca1780ad9252
--- /dev/null
+++ b/dev-python/oct2py/oct2py-5.6.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=hatchling
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python to GNU Octave bridge"
+HOMEPAGE="
+	https://github.com/blink1073/oct2py
+	https://blink1073.github.io/oct2py/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/numpy-1.12[${PYTHON_USEDEP}]
+	>=dev-python/octave_kernel-0.34.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-0.17[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+	)"
+
+EPYTEST_DESELECT=(
+	# No graphics toolkit available: 743589
+	"oct2py/ipython/tests/test_octavemagic.py::OctaveMagicTest::test_octave_plot"
+)
+
+distutils_enable_sphinx docs/source \
+	dev-python/numpydoc \
+	dev-python/sphinx-bootstrap-theme \
+	dev-python/sphinx-rtd-theme \
+	dev-python/myst-parser
+distutils_enable_tests pytest
+
+PATCHES=( "${FILESDIR}"/${PN}-5.2.0-mask-pkg-load-test.patch )
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3