From 590b9b7b03bf4651e099949e318755af7cfa81b8 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 1 Aug 2021 22:03:23 +0100
Subject: gentoo resync : 01.08.2021

---
 dev-python/pycdio/pycdio-2.1.1.ebuild | 40 +++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 dev-python/pycdio/pycdio-2.1.1.ebuild

(limited to 'dev-python/pycdio/pycdio-2.1.1.ebuild')

diff --git a/dev-python/pycdio/pycdio-2.1.1.ebuild b/dev-python/pycdio/pycdio-2.1.1.ebuild
new file mode 100644
index 000000000000..635e1a54c837
--- /dev/null
+++ b/dev-python/pycdio/pycdio-2.1.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Python OO interface to libcdio (CD Input and Control library)"
+HOMEPAGE="https://savannah.gnu.org/projects/libcdio/ https://pypi.org/project/pycdio/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+BDEPEND="dev-lang/swig"
+DEPEND=">=dev-libs/libcdio-2.0.0"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# Remove obsolete sys.path and adjust 'data' paths in examples.
+	sed -i \
+		-e "s:^sys.path.insert.*::" \
+		-e "s:\.\./data:./data:g" \
+		example/*.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3