From 95b557bc48bb734c288bac87dcfe98b8ae3d1cdb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 18 Jan 2023 11:56:49 +0000
Subject: gentoo auto-resync : 18:01:2023 - 11:56:49

---
 dev-python/pydocstyle/pydocstyle-6.3.0.ebuild | 48 +++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-python/pydocstyle/pydocstyle-6.3.0.ebuild

(limited to 'dev-python/pydocstyle/pydocstyle-6.3.0.ebuild')

diff --git a/dev-python/pydocstyle/pydocstyle-6.3.0.ebuild b/dev-python/pydocstyle/pydocstyle-6.3.0.ebuild
new file mode 100644
index 000000000000..4a3853bdbf36
--- /dev/null
+++ b/dev-python/pydocstyle/pydocstyle-6.3.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( pypy3 python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python docstring style checker"
+HOMEPAGE="
+	https://github.com/PyCQA/pydocstyle/
+	https://pypi.org/project/pydocstyle/
+"
+SRC_URI="
+	https://github.com/PyCQA/pydocstyle/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/snowballstemmer-2.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/tomli[${PYTHON_USEDEP}]
+		' 3.{8..10})
+	)
+"
+
+distutils_enable_tests pytest
+# Requires network to lookup github issues
+#distutils_enable_sphinx docs dev-python/sphinx_rtd_theme dev-python/sphinxcontrib-issuetracker
+
+PATCHES=(
+	"${FILESDIR}"/pydocstyle-6.1.1-disarm-pip-install.patch
+)
+
+src_prepare() {
+	# poetry sucks
+	sed -i -e "s:0.0.0-dev:${PV}:" pyproject.toml || die
+	distutils-r1_src_prepare
+}
-- 
cgit v1.2.3