From 8d839e24e6b6e9a28d945d1dc094e65e2b0ccc2d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 11 Oct 2023 06:11:21 +0100
Subject: gentoo auto-resync : 11:10:2023 - 06:11:21

---
 dev-python/pypdf/pypdf-3.16.4.ebuild | 57 ++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 dev-python/pypdf/pypdf-3.16.4.ebuild

(limited to 'dev-python/pypdf/pypdf-3.16.4.ebuild')

diff --git a/dev-python/pypdf/pypdf-3.16.4.ebuild b/dev-python/pypdf/pypdf-3.16.4.ebuild
new file mode 100644
index 000000000000..036ff7bc421d
--- /dev/null
+++ b/dev-python/pypdf/pypdf-3.16.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+SAMPLE_COMMIT=d87c33efc0f98225132dfe9c47980208b8130aa4
+DESCRIPTION="Python library to work with PDF files"
+HOMEPAGE="
+	https://pypi.org/project/pypdf/
+	https://github.com/py-pdf/pypdf/
+"
+SRC_URI="
+	https://github.com/py-pdf/pypdf/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
+			-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		>=dev-python/pillow-8.0.0[jpeg,jpeg2k,tiff,${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# rely on -Werror
+	tests/test_utils.py::test_deprecate_no_replacement
+	tests/test_workflows.py::test_orientations
+	# TODO: requires fpdf
+	tests/test_page.py::test_compression
+	tests/test_writer.py::test_merging_many_temporary_files
+)
+
+src_unpack() {
+	default
+	if use test; then
+		mv "sample-files-${SAMPLE_COMMIT}"/* "${S}"/sample-files/ || die
+	fi
+}
+
+python_test() {
+	epytest -o addopts= -m "not enable_socket"
+}
-- 
cgit v1.2.3