From 0968caae52d6eae7513e2ce4e0900a2e009780ee Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 17 Sep 2023 11:03:04 +0100
Subject: gentoo auto-resync : 17:09:2023 - 11:03:03

---
 .../qscintilla-python-2.14.1.ebuild                | 80 ++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 dev-python/qscintilla-python/qscintilla-python-2.14.1.ebuild

(limited to 'dev-python/qscintilla-python/qscintilla-python-2.14.1.ebuild')

diff --git a/dev-python/qscintilla-python/qscintilla-python-2.14.1.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.14.1.ebuild
new file mode 100644
index 000000000000..0161c8b4a780
--- /dev/null
+++ b/dev-python/qscintilla-python/qscintilla-python-2.14.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit out-of-source-utils python-r1 qmake-utils
+
+DESCRIPTION="Python bindings for QScintilla"
+HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/ https://pypi.org/project/QScintilla/"
+
+MY_PN=QScintilla
+MY_P=${MY_PN}_src-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
+fi
+S=${WORKDIR}/${MY_P}/Python
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-python/PyQt5-5.15.5[gui,printsupport,widgets,${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	~x11-libs/qscintilla-${PV}:=
+"
+RDEPEND="${DEPEND}
+	>=dev-python/PyQt5-sip-12.12:=[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/PyQt-builder-1.15[${PYTHON_USEDEP}]
+	>=dev-python/sip-6.7[${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+"
+
+src_prepare() {
+	default
+	mv pyproject{-qt5,}.toml || die
+}
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			sip-build
+			--verbose
+			--build-dir="${BUILD_DIR}"
+			--scripts-dir="$(python_get_scriptdir)"
+			--qmake="$(qt5_get_bindir)"/qmake
+			--no-make
+			$(usev debug '--debug --qml-debug --tracing')
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Run eqmake to respect toolchain and build flags
+		run_in_build_dir eqmake5 -recursive ${MY_PN}.pro
+	}
+	python_foreach_impl configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+}
-- 
cgit v1.2.3