From 6c988f4ed171aed46326587a0ec0d64297b20f49 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 11 Mar 2024 00:45:39 +0000
Subject: gentoo auto-resync : 11:03:2024 - 00:45:38

---
 dev-python/scikit-learn/Manifest                   |  3 +
 dev-python/scikit-learn/metadata.xml               | 17 +++++
 .../scikit-learn/scikit-learn-1.3.2-r1.ebuild      | 78 ++++++++++++++++++++++
 3 files changed, 98 insertions(+)
 create mode 100644 dev-python/scikit-learn/Manifest
 create mode 100644 dev-python/scikit-learn/metadata.xml
 create mode 100644 dev-python/scikit-learn/scikit-learn-1.3.2-r1.ebuild

(limited to 'dev-python/scikit-learn')

diff --git a/dev-python/scikit-learn/Manifest b/dev-python/scikit-learn/Manifest
new file mode 100644
index 000000000000..93c832da8178
--- /dev/null
+++ b/dev-python/scikit-learn/Manifest
@@ -0,0 +1,3 @@
+DIST scikit-learn-1.3.2.gh.tar.gz 7650823 BLAKE2B 170699917f46d6d3f4b9ebc314bc1ec45687dad0a4aec5d2cee6e288b5dbe508bad6dd80406501f289a33593c6482067393e9dc28155f85a4872a34523bf4199 SHA512 a3799e9b39b755a50ba225f836904a378f7d83a08274c614d0485e4d4d4a7b0c7adba2dbb6612f2ccb4e5167f872214a2853eff69d767dc70f52369bda7a230b
+EBUILD scikit-learn-1.3.2-r1.ebuild 1937 BLAKE2B 633a70b5f27f2ad9a3e1ccbc0f560aa3e4e41768827d2fe7f89009712c105829a545de79b2acdb7e45d7ff4f83d555ba138f4bbff76038474996e2fa8eec3b78 SHA512 b09e1c642450e0bc10b213a3171962dd262f550926424c10de11711597c70c0915a140a30ffe6f255c5751bce9938b7874a0b9feebc51d71d042830f1991e7b6
+MISC metadata.xml 614 BLAKE2B b5425c2d022592581647c9b97c0ab22bfc2afe347b2e5ea22f141245238f145322f39406c62318ba1e6af1462b2691267b39976bfde38faaf1d28b1d29c4e015 SHA512 74ac79123848bc385c29fcfdc4a1e780529dda685c1deb5eb722f5d4919ee6ac9d80798d52c4af0be0cc8dbbaea3784963dd97e2b7c1258cc2f5605b0bc8907a
diff --git a/dev-python/scikit-learn/metadata.xml b/dev-python/scikit-learn/metadata.xml
new file mode 100644
index 000000000000..8700c73ecc29
--- /dev/null
+++ b/dev-python/scikit-learn/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    sklearn is a python library for machine learning. It aims to
+    implement classic machine learning algorithms while remaining simple
+    and efficient.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">scikit-learn</remote-id>
+    <remote-id type="github">scikit-learn/scikit-learn</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/dev-python/scikit-learn/scikit-learn-1.3.2-r1.ebuild b/dev-python/scikit-learn/scikit-learn-1.3.2-r1.ebuild
new file mode 100644
index 000000000000..1f42ebe8f21a
--- /dev/null
+++ b/dev-python/scikit-learn/scikit-learn-1.3.2-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="
+	https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn/
+	https://pypi.org/project/scikit-learn/
+"
+SRC_URI="
+	https://github.com/scikit-learn/scikit-learn/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ppc64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/wheel[${PYTHON_USEDEP}]
+	>=dev-python/joblib-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.22.3[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-2.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# test broken with newer scipy, fixed upstream
+		# https://github.com/scikit-learn/scikit-learn/issues/27578
+		manifold/tests/test_locally_linear.py::test_singular_matrix
+		# TODO
+		gaussian_process/kernels.py::sklearn.gaussian_process.kernels.ExpSineSquared
+	)
+
+	rm -rf sklearn || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest --pyargs sklearn
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete || die
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}
-- 
cgit v1.2.3