From b1c81de4fadbd00897700a7321f03b390d952b2e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Thu, 26 Aug 2021 00:09:36 +0100
Subject: gentoo resync : 26.08.2021

---
 dev-qt/qtchooser/Manifest               |  1 +
 dev-qt/qtchooser/qtchooser-66-r1.ebuild | 73 +++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)
 create mode 100644 dev-qt/qtchooser/qtchooser-66-r1.ebuild

(limited to 'dev-qt/qtchooser')

diff --git a/dev-qt/qtchooser/Manifest b/dev-qt/qtchooser/Manifest
index f13863183989..66491f7796a5 100644
--- a/dev-qt/qtchooser/Manifest
+++ b/dev-qt/qtchooser/Manifest
@@ -1,3 +1,4 @@
 DIST qtchooser-66.tar.xz 32008 BLAKE2B 1faf4a44406655621e65132289af6a8b0d23f0c1027a3b99017c3951705378bebcfbc3cb32aa59975a101f21294ff701ca6eb6ec18ce977b714a426be0fbcd6d SHA512 0c7d3588ddd7b21e6e9d799204924e06e0b0950c898dfd23088f1e7657b7f821a35579aa062658499809f9d9757e82c3c592591aa2e5ec453463929bf2b33bac
+EBUILD qtchooser-66-r1.ebuild 1475 BLAKE2B f3d1494004ab280f42e2bd439a3832012ebb69b175faa806135478f9bb95441a2bf18aba0ce988381b06ba04ea48448f4e2f0f56c9c34244fc991647c19ba92f SHA512 9d67d5c439565e31593babed7ea27aa838cba849bb592c0c6ba9ada00a68959b926c3234db40a81cb530f988d5c7d6a775b6b000ff49ef454c901812171a13b3
 EBUILD qtchooser-66.ebuild 977 BLAKE2B a28e55c2c6f55082c93f8d7ba3e1e0d4b5cc378663ae94cd0026a46745625e1f7240cba603458ab756ced69950c3059a8bb63b94b7b45f96f0d783d542f9c823 SHA512 a10663af25e02e9f59bf3d9bf93ce5662bce5dd489382916e7396350d7dd738cea432ae8aaede433bee6a3db378e79d23ce0a8af063d7d5c2f99c5c6887c1765
 MISC metadata.xml 247 BLAKE2B 1428e575bd9b69424c4711499480493ae371840c146149819dc41c38335cbd16d7ce50ce8f6b7be1b77db73092ed6900a9a2d8032cc790058a56e533b01f562d SHA512 b43c8e84c3c753b49b203921a5aca792639a36d6efdbe16c069ff9abfbce0585718bb3824c03abdd7bd19ada13fb0a98a378c85ed369ac5fdc53ad3b3d5465d2
diff --git a/dev-qt/qtchooser/qtchooser-66-r1.ebuild b/dev-qt/qtchooser/qtchooser-66-r1.ebuild
new file mode 100644
index 000000000000..46e2087883e4
--- /dev/null
+++ b/dev-qt/qtchooser/qtchooser-66-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qmake-utils toolchain-funcs
+
+DESCRIPTION="Tool to quickly switch between multiple Qt installations"
+HOMEPAGE="https://code.qt.io/cgit/qtsdk/qtchooser.git/"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://code.qt.io/qtsdk/qtchooser.git"
+	inherit git-r3
+else
+	SRC_URI="http://download.qt.io/official_releases/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="|| ( LGPL-2.1 GPL-3 )"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? (
+		dev-qt/qtcore:5
+		dev-qt/qttest:5
+	)"
+RDEPEND="
+	!<dev-qt/qtcore-5.15.2-r10:5
+"
+
+qtchooser_make() {
+	emake \
+		CXX="$(tc-getCXX)" \
+		LFLAGS="${LDFLAGS}" \
+		prefix="${EPREFIX}/usr" \
+		"$@"
+}
+
+src_compile() {
+	qtchooser_make
+}
+
+src_test() {
+	pushd tests/auto >/dev/null || die
+	eqmake5
+	popd >/dev/null || die
+
+	qtchooser_make check
+}
+
+src_install() {
+	qtchooser_make INSTALL_ROOT="${D}" install
+
+	# install configuration file
+	cat > "${T}/qt5-${CHOST}.conf" <<-_EOF_ || die
+		$(qt5_get_bindir)
+		$(qt5_get_libdir)
+	_EOF_
+
+	(
+		insinto /etc/xdg/qtchooser
+		doins "${T}/qt5-${CHOST}.conf"
+	)
+
+	# convenience symlinks
+	dosym qt5-"${CHOST}".conf /etc/xdg/qtchooser/5.conf
+	dosym qt5-"${CHOST}".conf /etc/xdg/qtchooser/qt5.conf
+	dosym qt5.conf /etc/xdg/qtchooser/default.conf
+
+	# TODO: bash and zsh completion
+	# newbashcomp scripts/${PN}.bash ${PN}
+}
-- 
cgit v1.2.3