From 2fd57282f0262ca084e05b0f2c63fbada395d02b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 16 Jan 2022 20:27:28 +0000
Subject: gentoo resync : 16.01.2021

---
 dev-util/amtterm/Manifest              |  2 +-
 dev-util/amtterm/amtterm-1.6-r1.ebuild | 49 ++++++++++++++++++++++++++++++++++
 dev-util/amtterm/amtterm-1.6.ebuild    | 46 -------------------------------
 3 files changed, 50 insertions(+), 47 deletions(-)
 create mode 100644 dev-util/amtterm/amtterm-1.6-r1.ebuild
 delete mode 100644 dev-util/amtterm/amtterm-1.6.ebuild

(limited to 'dev-util/amtterm')

diff --git a/dev-util/amtterm/Manifest b/dev-util/amtterm/Manifest
index aecbb79b93a3..1ce8031c3f65 100644
--- a/dev-util/amtterm/Manifest
+++ b/dev-util/amtterm/Manifest
@@ -1,3 +1,3 @@
 DIST amtterm-1.6.tar.gz 40804 BLAKE2B a682bb6646e7ed57e3ee8f17f25bdd60fed37d614eb3e66f6b05fa4062ef99237c24d69e4795e7a9d8b83579728c8f8423389bf7e042d981b3e84a0037e56b0d SHA512 b10777727cf7f931e4b04fff7c621ea6e94989738833fe4f830bd795c8be3b0e983100b34a2ea5feb48221f022b3498a819c9f4fba9c7722226d56d374a1d986
-EBUILD amtterm-1.6.ebuild 993 BLAKE2B f99b9b674619d58b2b27cb0350ae568ea41a20efa2fcf23a731920ecdc0fd44d81a5631aa1b1161cfd1993395c15cf4cbdbacd4695efd6384b75a27a6f5a0255 SHA512 5a29fe5aff274d0ec95f8a02eac2bea254eccdd424d2f6674b74dc1930d36747f8d68291a22f509fe60c6a103b3ee1e3727017a2ebe0d2e55c23e5a6b6fe0d04
+EBUILD amtterm-1.6-r1.ebuild 1011 BLAKE2B 9ecc65b4d58317e0eeebc6e0cb6a4d2b80d933d328375894df944a03bf2ef319ff43126afe4195eaf89e9811dcece2f084256d1d10efa28c7c5cadefe4c7486b SHA512 57dc03ccf21255e9044955eca8220825c467a1e2c9039906d15385b6f33192aa554a71aa4cb5804fab87fe3cd212dfa72a309cd3e5ca01fac56fbf32235a13c2
 MISC metadata.xml 248 BLAKE2B 2ac829e1663815f752e218e9ee474448a3d973c075939d578699f57790581498adfe9bad180a79fcc6ea0afc339f57d25cbcc0fdd430f82d192c23c03d15e465 SHA512 55c2e2e06f91e13fd73b9545c51d4169a47f040ead41eb1368479940b026def820de67137312b64a6203f80b57a421c8895ed690386a79086fa0ba6c3557aa47
diff --git a/dev-util/amtterm/amtterm-1.6-r1.ebuild b/dev-util/amtterm/amtterm-1.6-r1.ebuild
new file mode 100644
index 000000000000..d9a6a8dc663e
--- /dev/null
+++ b/dev-util/amtterm/amtterm-1.6-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="A nice tool to manage amt-enabled machines"
+HOMEPAGE="https://www.kraxel.org/blog/linux/amtterm/"
+SRC_URI="https://www.kraxel.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+IUSE="gtk"
+
+DEPEND="
+	gtk? (
+		x11-libs/gtk+:3
+		x11-libs/vte:2.91
+	)
+"
+RDEPEND="${DEPEND}
+	dev-perl/SOAP-Lite
+"
+
+src_prepare() {
+	default
+	sed -i -e 's|\(INSTALL_BINARY  := \$(INSTALL)\) \$(STRIP)|\1|' mk/Variables.mk || die
+}
+
+src_configure() {
+	echo "LIB := $(get_libdir)" > Make.config || die
+
+	# enable gamt
+	echo "HAVE_GTK := $(usex gtk)" >> Make.config || die
+	echo "HAVE_VTE := $(usex gtk)" >> Make.config || die
+}
+
+src_compile() {
+	emake prefix="${EPREFIX}"/usr
+}
+
+src_install() {
+	emake prefix="${EPREFIX}"/usr DESTDIR="${D}" install
+
+	if ! use gtk; then
+		rm -r "${ED}"/usr/share/applications || die
+		rm -r "${ED}"/usr/share/man/man1/gamt* || die
+	fi
+}
diff --git a/dev-util/amtterm/amtterm-1.6.ebuild b/dev-util/amtterm/amtterm-1.6.ebuild
deleted file mode 100644
index 7f7b43b37eb4..000000000000
--- a/dev-util/amtterm/amtterm-1.6.ebuild
+++ /dev/null
@@ -1,46 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-
-inherit eutils
-
-DESCRIPTION="A nice tool to manage amt-enabled machines"
-HOMEPAGE="https://www.kraxel.org/blog/linux/amtterm/"
-SRC_URI="https://www.kraxel.org/releases/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux"
-IUSE="gtk"
-
-DEPEND="gtk? (
-	x11-libs/gtk+:3
-	x11-libs/vte:2.91 )"
-RDEPEND="${DEPEND}
-	dev-perl/SOAP-Lite"
-
-src_prepare() {
-	sed -i -e 's|\(INSTALL_BINARY  := \$(INSTALL)\) \$(STRIP)|\1|' mk/Variables.mk || die
-}
-
-src_configure() {
-	echo "LIB := $(get_libdir)" > Make.config || die
-
-	# enable gamt
-	echo "HAVE_GTK := $(usex gtk)" >> Make.config || die
-	echo "HAVE_VTE := $(usex gtk)" >> Make.config || die
-}
-
-src_compile() {
-	prefix="/usr" emake
-}
-
-src_install() {
-	prefix="/usr" emake DESTDIR=${ED} install
-
-	if ! use gtk; then
-		rm -rf "${D}"/usr/share/applications || die
-		rm -rf "${D}"/usr/share/man/man1/gamt* || die
-	fi
-}
-- 
cgit v1.2.3