From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 dev-util/anjuta/anjuta-3.34.0-r2.ebuild | 53 +++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-util/anjuta/anjuta-3.34.0-r2.ebuild

(limited to 'dev-util/anjuta/anjuta-3.34.0-r2.ebuild')

diff --git a/dev-util/anjuta/anjuta-3.34.0-r2.ebuild b/dev-util/anjuta/anjuta-3.34.0-r2.ebuild
new file mode 100644
index 000000000000..fad8dc7ade3c
--- /dev/null
+++ b/dev-util/anjuta/anjuta-3.34.0-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2
+
+DESCRIPTION="Base library of defunct IDE for GNOME to run applications"
+HOMEPAGE="https://wiki.gnome.org/Apps/Anjuta https://gitlab.gnome.org/Archive/anjuta"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+DEPEND="
+	>=dev-libs/gdl-3.5.5:3=
+	>=dev-libs/glib-2.34:2[dbus]
+	>=dev-libs/libxml2-2.4.23
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.10:3
+	x11-libs/pango
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PV}-minimal.patch
+)
+
+LA="libanjuta-${PV%%.*}.la"
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-debug \
+		--disable-introspection \
+		--disable-neon \
+		--disable-nls \
+		--disable-plugin-subversion \
+		--disable-serf \
+		--disable-static
+}
+
+src_compile() {
+	emake -C libanjuta/interfaces libanjuta-interfaces.la
+	emake -C libanjuta ${LA}
+}
+
+src_install() {
+	emake DESTDIR="${D}" -C libanjuta install-am
+	emake DESTDIR="${D}" -C libanjuta/interfaces install-am
+	emake DESTDIR="${D}" -C src install-dist_anjuta_pixmapsDATA
+	rm -v "${ED}"/usr/$(get_libdir)/${LA} || die
+}
-- 
cgit v1.2.3