From f704f050bfdcc3bad4cd597edcce143ca6133848 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 6 Mar 2023 23:55:40 +0000
Subject: gentoo auto-resync : 06:03:2023 - 23:55:39

---
 dev-util/bpftool/bpftool-6.1.7.ebuild | 123 ----------------------------------
 1 file changed, 123 deletions(-)
 delete mode 100644 dev-util/bpftool/bpftool-6.1.7.ebuild

(limited to 'dev-util/bpftool/bpftool-6.1.7.ebuild')

diff --git a/dev-util/bpftool/bpftool-6.1.7.ebuild b/dev-util/bpftool/bpftool-6.1.7.ebuild
deleted file mode 100644
index 5e04ebcc3cf1..000000000000
--- a/dev-util/bpftool/bpftool-6.1.7.ebuild
+++ /dev/null
@@ -1,123 +0,0 @@
-# Copyright 2021-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{9..11} )
-inherit estack linux-info optfeature python-any-r1 bash-completion-r1 toolchain-funcs
-
-MY_PV="${PV/_/-}"
-MY_PV="${MY_PV/-pre/-git}"
-
-DESCRIPTION="Tool for inspection and simple manipulation of eBPF programs and maps"
-HOMEPAGE="https://kernel.org/"
-
-LINUX_V="${PV:0:1}.x"
-LINUX_VER=$(ver_cut 1-2)
-LINUX_PATCH=patch-${PV}.xz
-SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_PATCH}"
-
-LINUX_SOURCES="linux-${LINUX_VER}.tar.xz"
-SRC_URI+=" https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_SOURCES}"
-
-S_K="${WORKDIR}/linux-${LINUX_VER}"
-S="${S_K}/tools/bpf/bpftool"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
-IUSE="caps"
-
-RDEPEND="
-	sys-libs/binutils-libs:=
-	sys-libs/zlib:=
-	virtual/libelf:=
-	caps? ( sys-libs/libcap:= )
-"
-DEPEND="
-	${RDEPEND}
-	>=sys-kernel/linux-headers-5.8
-"
-BDEPEND="
-	${LINUX_PATCH+dev-util/patchutils}
-	${PYTHON_DEPS}
-	app-arch/tar
-	dev-python/docutils
-"
-
-CONFIG_CHECK="~DEBUG_INFO_BTF"
-
-# src_unpack and src_prepare are copied from dev-util/perf since
-# it's building from the same tarball, please keep it in sync with perf
-src_unpack() {
-	local paths=(
-		tools/bpf kernel/bpf
-		tools/{arch,build,include,lib,perf,scripts} {scripts,include,lib} "arch/*/lib"
-	)
-
-	# We expect the tar implementation to support the -j and --wildcards option
-	echo ">>> Unpacking ${LINUX_SOURCES} (${paths[*]}) to ${PWD}"
-	gtar --wildcards -xpf "${DISTDIR}"/${LINUX_SOURCES} \
-		"${paths[@]/#/linux-${LINUX_VER}/}" || die
-
-	if [[ -n ${LINUX_PATCH} ]] ; then
-		eshopts_push -o noglob
-		ebegin "Filtering partial source patch"
-		filterdiff -p1 ${paths[@]/#/-i } -z "${DISTDIR}"/${LINUX_PATCH} \
-			> ${P}.patch
-		eend $? || die "filterdiff failed"
-		eshopts_pop
-	fi
-
-	local a
-	for a in ${A}; do
-		[[ ${a} == ${LINUX_SOURCES} ]] && continue
-		[[ ${a} == ${LINUX_PATCH} ]] && continue
-		unpack ${a}
-	done
-}
-
-src_prepare() {
-	default
-
-	if [[ -n ${LINUX_PATCH} ]] ; then
-		pushd "${S_K}" >/dev/null || die
-		eapply "${WORKDIR}"/${P}.patch
-		popd || die
-	fi
-
-	pushd "${S_K}" >/dev/null || die
-	# bug #890638
-	eapply "${FILESDIR}"/5.19.12-no-stack-protector.patch
-	popd || die
-
-	# dev-python/docutils installs rst2man.py, not rst2man
-	sed -i -e 's/rst2man/rst2man.py/g' Documentation/Makefile || die
-}
-
-bpftool_make() {
-	local arch=$(tc-arch-kernel)
-	tc-export AR CC LD
-
-	emake V=1 VF=1 \
-		HOSTCC="$(tc-getBUILD_CC)" HOSTLD="$(tc-getBUILD_LD)" \
-		EXTRA_CFLAGS="${CFLAGS}" ARCH="${arch}" BPFTOOL_VERSION="${MY_PV}" \
-		prefix="${EPREFIX}"/usr \
-		bash_compdir="$(get_bashcompdir)" \
-		feature-libcap="$(usex caps 1 0)" \
-		"$@"
-}
-
-src_compile() {
-	bpftool_make
-	bpftool_make -C Documentation
-}
-
-src_install() {
-	bpftool_make DESTDIR="${D}" install
-	bpftool_make mandir="${ED}"/usr/share/man -C Documentation install
-}
-
-pkg_postinst() {
-	optfeature "clang-bpf-co-re support" sys-devel/clang[llvm_targets_BPF]
-}
-- 
cgit v1.2.3