From 3517852e3b8a68d1e997770fc0650c5053bafc6c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 4 Jan 2022 01:27:12 +0000
Subject: gentoo resync : 04.01.2022

---
 dev-util/cflow/cflow-1.7.ebuild | 57 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 dev-util/cflow/cflow-1.7.ebuild

(limited to 'dev-util/cflow/cflow-1.7.ebuild')

diff --git a/dev-util/cflow/cflow-1.7.ebuild b/dev-util/cflow/cflow-1.7.ebuild
new file mode 100644
index 000000000000..505e9785fbf2
--- /dev/null
+++ b/dev-util/cflow/cflow-1.7.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp-common
+
+DESCRIPTION="C function call hierarchy analyzer"
+HOMEPAGE="https://www.gnu.org/software/cflow/"
+SRC_URI="http://ftp.gnu.org/gnu/cflow/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug emacs nls"
+
+RDEPEND="emacs? ( >=app-editors/emacs-23.1:* )
+	nls? ( virtual/libintl virtual/libiconv )"
+DEPEND="nls? ( virtual/libintl virtual/libiconv )"
+BDEPEND="emacs? ( >=app-editors/emacs-23.1:* )
+	sys-devel/flex
+	nls? ( sys-devel/gettext )"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable debug) \
+		EMACS=no
+}
+
+src_compile() {
+	default
+
+	if use emacs; then
+		elisp-compile elisp/cflow-mode.el
+	fi
+}
+
+src_install() {
+	default
+	doinfo doc/cflow.info
+
+	if use emacs; then
+		elisp-install ${PN} elisp/cflow-mode.{el,elc}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
-- 
cgit v1.2.3