From a4f9ab81d6cbfc3ff649dd3577e3efa700b47387 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 6 Oct 2022 01:20:42 +0100
Subject: gentoo auto-resync : 06:10:2022 - 01:20:42

---
 dev-util/clion/clion-2022.2.1-r2.ebuild | 112 ++++++++++++++++++++++++++++++++
 1 file changed, 112 insertions(+)
 create mode 100644 dev-util/clion/clion-2022.2.1-r2.ebuild

(limited to 'dev-util/clion/clion-2022.2.1-r2.ebuild')

diff --git a/dev-util/clion/clion-2022.2.1-r2.ebuild b/dev-util/clion/clion-2022.2.1-r2.ebuild
new file mode 100644
index 000000000000..5877a908c2d6
--- /dev/null
+++ b/dev-util/clion/clion-2022.2.1-r2.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop wrapper
+
+DESCRIPTION="A complete toolset for C and C++ development"
+HOMEPAGE="https://www.jetbrains.com/clion"
+SRC_URI="https://download.jetbrains.com/cpp/CLion-${PV}.tar.gz"
+
+LICENSE="|| ( IDEA IDEA_Academic IDEA_Classroom IDEA_OpenSource IDEA_Personal )
+	Apache-1.1 Apache-2.0 BSD BSD-2 CC0-1.0 CDDL-1.1 CPL-0.5 CPL-1.0
+	EPL-1.0 EPL-2.0 GPL-2 GPL-2-with-classpath-exception GPL-3 ISC JDOM
+	LGPL-2.1+ LGPL-3 MIT MPL-1.0 MPL-1.1 OFL public-domain PSF-2 UoI-NCSA ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="bindist mirror splitdebug"
+
+BDEPEND="dev-util/patchelf"
+
+# RDEPENDS may cause false positives in repoman.
+# clion requires cmake and gdb at runtime to build and debug C/C++ projects
+RDEPEND="
+	|| (
+		>=app-accessibility/at-spi2-core-2.46.0:2
+		( app-accessibility/at-spi2-atk dev-libs/atk )
+	)
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-util/cmake
+	dev-util/ninja
+	media-libs/alsa-lib
+	media-libs/freetype:2
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-devel/gdb
+	x11-libs/cairo
+	x11-libs/pango
+	sys-libs/zlib
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libXxf86vm
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon"
+
+QA_PREBUILT="opt/${P}/*"
+
+src_prepare() {
+	default
+
+	local remove_me=(
+		bin/cmake
+		bin/lldb/linux
+		bin/gdb/linux
+		bin/ninja
+		license/CMake*
+		lib/pty4j-native/linux/aarch64
+		lib/pty4j-native/linux/arm
+		lib/pty4j-native/linux/mips64el
+		lib/pty4j-native/linux/ppc64le
+		plugins/remote-dev-server/selfcontained
+		plugins/cwm-plugin/quiche-native/linux-aarch64
+	)
+
+	use amd64 || remove_me+=( lib/pty4j-native/linux/x86_64 )
+	use x86 || remove_me+=( lib/pty4j-native/linux/x86 )
+
+	rm -rv "${remove_me[@]}" || die
+
+	for file in "jbr/lib/"/{libjcef.so,jcef_helper}
+	do
+		if [[ -f "${file}" ]]; then
+			patchelf --set-rpath '$ORIGIN' ${file} || die
+		fi
+	done
+}
+
+src_install() {
+	local dir="/opt/${P}"
+
+	insinto "${dir}"
+	doins -r *
+	fperms 755 "${dir}"/bin/{clion.sh,fsnotifier,inspect.sh,ltedit.sh,repair,clang/linux/{clangd,clang-tidy,clazy-standalone,llvm-symbolizer}}
+
+	if [[ -d jbr ]]; then
+		fperms 755 "${dir}"/jbr/bin/{java,javac,jdb,jrunscript,keytool,rmiregistry,serialver}
+		# Fix #763582
+		fperms 755 "${dir}"/jbr/lib/{chrome-sandbox,jcef_helper,jexec,jspawnhelper}
+	fi
+	dosym -r "${EPREFIX}/usr/bin/ninja" "${dir}"/bin/ninja/linux/ninja
+
+	make_wrapper "${PN}" "${dir}/bin/${PN}.sh"
+	newicon "bin/${PN}.svg" "${PN}.svg"
+	make_desktop_entry "${PN}" "CLion" "${PN}" "Development;IDE;"
+
+	# recommended by: https://confluence.jetbrains.com/display/IDEADEV/Inotify+Watches+Limit
+	dodir /usr/lib/sysctl.d/
+	echo "fs.inotify.max_user_watches = 524288" > "${D}/usr/lib/sysctl.d/30-clion-inotify-watches.conf" || die
+}
-- 
cgit v1.2.3