From eccb70a7f91b2d22582587f26d1a28bb31408b45 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 18 May 2019 00:10:51 +0100
Subject: gentoo resync : 18.05.2019

---
 dev-util/edi/edi-0.7.1.ebuild | 58 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-util/edi/edi-0.7.1.ebuild

(limited to 'dev-util/edi/edi-0.7.1.ebuild')

diff --git a/dev-util/edi/edi-0.7.1.ebuild b/dev-util/edi/edi-0.7.1.ebuild
new file mode 100644
index 000000000000..7a4dcb2ba8a2
--- /dev/null
+++ b/dev-util/edi/edi-0.7.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit llvm meson xdg-utils
+
+DESCRIPTION="An EFL-based IDE"
+HOMEPAGE="https://www.enlightenment.org/about-edi"
+SRC_URI="https://github.com/Enlightenment/edi/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1-with-linking-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clang"
+
+RDEPEND="|| ( dev-libs/efl[X] dev-libs/efl[wayland] )
+	>=dev-libs/efl-1.22.0[eet]
+	clang? ( sys-devel/clang:= )"
+DEPEND="${RDEPEND}
+	dev-libs/check"
+BDEPEND=">=dev-util/meson-0.50.0
+	virtual/pkgconfig"
+
+llvm_check_deps() {
+	has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	use clang && llvm_pkg_setup
+}
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# fix a QA issue with .desktop file, https://phab.enlightenment.org/T7368
+	sed -i '/Version=/d' data/desktop/edi.desktop* || die
+
+	# fix 'unexpected path' QA warning
+	sed -i 's|share/doc/edi/|share/doc/'${PF}'/|g' doc/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-D bear=false
+		$(meson_use clang libclang)
+	)
+
+	if use clang; then
+		emesonargs+=(
+			-D libclang-headerdir="$(llvm-config --includedir)"
+			-D libclang-libdir="$(llvm-config --libdir)"
+		)
+	fi
+
+	meson_src_configure
+}
-- 
cgit v1.2.3