From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 .../kdstatemachineeditor-9999.ebuild               | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-util/kdstatemachineeditor/kdstatemachineeditor-9999.ebuild

(limited to 'dev-util/kdstatemachineeditor/kdstatemachineeditor-9999.ebuild')

diff --git a/dev-util/kdstatemachineeditor/kdstatemachineeditor-9999.ebuild b/dev-util/kdstatemachineeditor/kdstatemachineeditor-9999.ebuild
new file mode 100644
index 000000000000..5711b07e35a0
--- /dev/null
+++ b/dev-util/kdstatemachineeditor/kdstatemachineeditor-9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils kde5-functions
+
+DESCRIPTION="Framework for creating Qt State Machine metacode using graphical user interfaces"
+HOMEPAGE="https://github.com/KDAB/KDStateMachineEditor"
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/KDAB/KDStateMachineEditor.git"
+else
+	SRC_URI="https://github.com/KDAB/KDStateMachineEditor/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2+"
+IUSE="doc test"
+SLOT="0"
+
+RDEPEND="
+	$(add_qt_dep qtcore)
+	$(add_qt_dep qtdeclarative 'widgets')
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+"
+
+DEPEND="${RDEPEND}
+	doc? (
+		$(add_qt_dep qthelp)
+		app-doc/doxygen
+	)
+	test? (
+		$(add_qt_dep qttest)
+		$(add_qt_dep qtxmlpatterns)
+	)
+	media-gfx/graphviz
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_DOCS=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+	)
+	cmake-utils_src_configure
+}
-- 
cgit v1.2.3