From 162945d2a91899b637bbb9e163b406350de12906 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 30 Oct 2021 19:43:03 +0100
Subject: gentoo resync : 30.10.2021

---
 dev-util/ostree/Manifest             |   2 +
 dev-util/ostree/ostree-2021.5.ebuild | 106 +++++++++++++++++++++++++++++++++++
 2 files changed, 108 insertions(+)
 create mode 100644 dev-util/ostree/ostree-2021.5.ebuild

(limited to 'dev-util/ostree')

diff --git a/dev-util/ostree/Manifest b/dev-util/ostree/Manifest
index 4b8805cc7fb4..9360eaca0e9a 100644
--- a/dev-util/ostree/Manifest
+++ b/dev-util/ostree/Manifest
@@ -1,5 +1,7 @@
 DIST ostree-2021.3.tar.xz 2089804 BLAKE2B 5df33b676173b1ec08ac7592d4ddf8e3bfdcd84df1b3ce19e2f24c85780fed1f210b8adce1baf4ec87869c72984502276bf6e5a72268daaae6ce9b3d6dc6f88b SHA512 0df0d8f9bd82b16562dd5146997eddfb7cb6cffc1886601307d97a1cb1dc926bda7d0c899db26c974ed0dff1012dee11937e47c11c4d03307fa3d2d430adc60e
 DIST ostree-2021.4.tar.xz 2048424 BLAKE2B 386ed38f6dc8035a429505d8392682f739bc9a57a8cf9d7960942cd0ff0b61eee314116866c3b520d802a3f16f6dfecd1ea45a7b1d44cac8d065ad56a1ed2c2f SHA512 9bde7281afa456b30253149639854f579c1f1bdf6c429059eeb69042515b5ebfdf6426b4c9780ca8e700a11f0ec05cfc03e48baa8d0858ddbca7d3942aab9bbd
+DIST ostree-2021.5.tar.xz 2049572 BLAKE2B 946e863470e53a27f9936e224e2fdf00aa70c47d141b4101e00935f597aee037fd60d0d5660e7f41cb7a3fc7051a5f286a96e10a16b7f35da2be26c29c745346 SHA512 73d463e9cfaa027ac640051615b312c1800e71b2587e33cbae1e60356cb3c3f5d4afcda8ace680636ebd1d112061f2a8a7c25c46aa24a1b260244451157ffe8a
 EBUILD ostree-2021.3-r2.ebuild 2572 BLAKE2B b8f71329ad5cb45ed8997eb3c95f595d49cf1c58dc86053b3ef1a8d7514c98e92e710b622013b3dba85affbcc6b249d97188a4dab9168062567a23ccdd5cc269 SHA512 db3f9b89e381d468032a66c4e3878dadb33b43e03ddf2cffcdf6fa825adb36527be119e0fc90e2caed7fb5071e544e5bda46c8684b1876c2fad6da48e211e609
 EBUILD ostree-2021.4-r1.ebuild 2626 BLAKE2B 8fbfe226dc7dc402afd4ad81de474359683e70f9b1f7ef7ac34b1f5a351d250531c985da12f317b16ef868e1abe2b8fb0a9827fe6606ec7d0f20852bf425fd75 SHA512 0848d822f107fd485661ce9d60aea8c8a06ff5e9193f815bc3f4fc120c7c78cac4b5bfdeac86f08b573b86110612be114405ab5191b979eb1652d3f4f3bd618d
+EBUILD ostree-2021.5.ebuild 2626 BLAKE2B 8fbfe226dc7dc402afd4ad81de474359683e70f9b1f7ef7ac34b1f5a351d250531c985da12f317b16ef868e1abe2b8fb0a9827fe6606ec7d0f20852bf425fd75 SHA512 0848d822f107fd485661ce9d60aea8c8a06ff5e9193f815bc3f4fc120c7c78cac4b5bfdeac86f08b573b86110612be114405ab5191b979eb1652d3f4f3bd618d
 MISC metadata.xml 1990 BLAKE2B 1c3e6400d24f0701211c0b8dcfba8d31c06b7c493cbe6eb2c5432ea818d0a0fbe863f8f1661eb386d179bb186cb7c970f7d7a3f8c9c42ea4b03b3d4ea0472a57 SHA512 04e37ddcd7348d43d475e04c996ee8b2e94c64143325dcfb21c5738b75f71ecd2c2ec64c8f91fbd06f5a6228671e90fdf10a939d4457abe4d0f88492435b4601
diff --git a/dev-util/ostree/ostree-2021.5.ebuild b/dev-util/ostree/ostree-2021.5.ebuild
new file mode 100644
index 000000000000..4c74aecc1d45
--- /dev/null
+++ b/dev-util/ostree/ostree-2021.5.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="Operating system and container binary deployment and upgrades"
+HOMEPAGE="https://ostreedev.github.io/ostree/"
+SRC_URI="https://github.com/ostreedev/ostree/releases/download/v${PV}/lib${P}.tar.xz -> ${P}.tar.xz"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+LICENSE="LGPL-2+"
+SLOT="0"
+
+IUSE="archive +curl doc dracut gnutls +gpg grub +http2 httpd introspection libmount selinux sodium ssl +soup systemd zeroconf"
+RESTRICT+=" test"
+REQUIRED_USE="
+	dracut? ( systemd )
+	http2? ( curl )
+	httpd? ( || ( curl soup ) )
+"
+
+COMMON_DEPEND="
+	app-arch/xz-utils
+	dev-libs/libassuan
+	dev-libs/glib:2
+	>=sys-fs/fuse-2.9.2:0
+	sys-libs/zlib
+	archive? ( app-arch/libarchive:= )
+	curl? ( net-misc/curl )
+	dracut? ( sys-kernel/dracut )
+	gpg? (
+		app-crypt/gpgme
+		dev-libs/libgpg-error
+	)
+	grub? ( sys-boot/grub:2= )
+	introspection? ( dev-libs/gobject-introspection )
+	libmount? ( sys-apps/util-linux )
+	selinux? ( sys-libs/libselinux )
+	sodium? ( >=dev-libs/libsodium-1.0.14:= )
+	soup? ( net-libs/libsoup:2.4 )
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? (
+			dev-libs/openssl:0=
+		)
+	)
+	systemd? ( sys-apps/systemd:0= )
+	zeroconf? ( net-dns/avahi[dbus] )"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	doc? ( dev-util/gtk-doc )"
+
+RDEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	sys-devel/flex
+	sys-devel/bison
+	virtual/pkgconfig"
+
+S="${WORKDIR}/lib${P}"
+
+src_prepare() {
+	sed -Ee 's:(XSLT_STYLESHEET = ).*:\1/usr/share/sgml/docbook/xsl-stylesheets/manpages/docbook.xsl:' \
+		-i Makefile.in Makefile-man.am || die
+	eautoreconf
+	default
+}
+
+src_configure() {
+	local econfargs=(
+		--enable-man
+		--enable-shared
+		$(use_with archive libarchive)
+		$(use_with curl)
+		$(use_with dracut dracut yesbutnoconf) #816867
+		$(use_enable doc gtk-doc)
+		$(usex introspection --enable-introspection={,} yes no)
+		$(use_with gpg gpgme)
+		$(use_enable http2)
+		$(use_enable httpd trivial-httpd-cmdline)
+		$(use_with selinux )
+		$(use_with soup)
+		$(use_with libmount)
+		$(use ssl && { use gnutls && echo --with-crypto=gnutls || echo --with-crypto=openssl; })
+		$(use_with sodium ed25519-libsodium)
+		$(use_with systemd libsystemd)
+		$(use_with zeroconf avahi)
+	)
+
+	if use systemd; then
+		econfargs+=(--with-systemdsystemunitdir="$(systemd_get_systemunitdir)")
+	fi
+
+	unset ${!XDG_*} #657346 g-ir-scanner sandbox violation
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+	rm -f "${ED}/etc/grub.d/15_ostree"
+}
-- 
cgit v1.2.3